Neo4j密码查询X染色体祖先

Question

在遗传谱系中，X染色体数据与某些祖先的联系很有用。这在以下位置得到了很好的说明： X-DNA遗传图

我的Neo4j数据库有每个人的节点以及连接他们的父亲和母亲的关系。每个节点都有一个属性性别（对于人的性别;M 或 F）。女性有两条X染色体，一条来自父母中的任何一方。男性有一条X染色体，总是来自母亲。

您可以使用reduce查看祖先继承所涉及的性别：

match p=(n:Person{RN:1})-[:father|mother*..20]->m 
return m.fullname as FullName
,reduce(status ='', q IN nodes(p)| status + q.sex) AS c 
order by length(p), c

因此，从男性（RN：1）开始，c的结果是他的父亲为MM，母亲为MF，外祖父为MMM，外祖父为MFM，依此类推。这种模式表明，当c包含MM（两个M依次在一起）时，这些MM对起始人的X染色体没有贡献。

我想删除任何具有 MM 模式的节点。使用外部代码很容易做到这一点，但我无法弄清楚如何在密码查询中做到这一点。

Answer 1

这应该适合您：

MATCH p=(n:Person { RN:1 })-[:father|mother*..20]->m
WITH m, NODES(p) AS a
WITH m, REDUCE(c = "", i IN RANGE(0, SIZE(a)-1)| CASE
  WHEN c IS NULL OR (i > 0 AND (a[i-1]).sex = "M" AND (a[i]).sex = "M") THEN
    NULL
  ELSE
    c + (a[i]).sex
  END ) AS c
WHERE c IS NOT NULL
RETURN m.fullName AS fullName, c
ORDER BY LENGTH(c);

下面是演示结果的控制台。

Answer 2

派对

有点晚了，思考过程与@cybersam的解决方案相同。

match p=(n:Person { RN: 1 })-[:father|mother*..20]->(m) 
with p, m, extract( g in nodes(p) | g.sex ) as genders
with p, m, genders, range(0,size(genders) -1,1) as gender_index
unwind gender_index as idx
with p, m, genders, collect([genders[idx], genders[idx+1]]) as pairs
where not ['M','M']  in pairs
return m.fullName
,reduce(status ='', q IN nodes(p)| status + q.sex) AS c 
order by length(p), c

Answer 3

这个查询只让我得到贡献 X 染色体的祖先：

match p=(n:Person{RN:1})-[:father|mother*..20]->(m)     
with m, reduce(status ='', q IN nodes(p)| status + q.sex) AS c     
where c=replace(c,'MM','') 
return m.RN,m.fullname as Name, c

性别

集合为每一代添加一个性别，并被过滤以排除任何MM，因为一个男性不能将他的X传递给另一个男性（例如，儿子）。