连接列表元素 - 方案

Question

如果我有一个生成以下结果的方案代码：（我正在使用缺点）

'((1 . 0) . 0)

我怎么能接受这个，只是简单地显示 100，就好像它只是一个整数，而不是一个用那些点和括号显示的列表？

谢谢！

编辑：

我的完整代码：

(define (func X) 
    (if ( <= X 3 )
       X
            (cons (modulo X 4) (func(floor(/ X 4)) ))  
))

Answer 1

如果我理解正确，您正在尝试将数字从基数 10 转换为基数 4，然后将其显示为数字，但您的实现存在几个问题。

你正在构建一个列表作为输出 - 但这不是你想要的，你想要一个数字。此外，您以错误的顺序遍历输入，这不是查找两个数字之间商的正确方法。也许这会有所帮助：

(define (func X)
  (let loop ((n X) (acc 0) (mult 1))
    (if (< n 4)
        (+ (* mult n) acc)
        (loop (quotient n 4)
              (+ (* mult (modulo n 4)) acc)
              (* mult 10)))))

或者，您可以输出一个字符串来强调输出不是以 10 为基数的事实：

(define (func X)
  (let loop ((n X) (acc ""))
    (if (< n 4)
        (string-append (number->string n) acc)
        (loop (quotient n 4)
              (string-append (number->string (modulo n 4)) acc)))))

它将按预期工作：

(func 16)
=> 100

Answer 2

奥斯卡·洛佩兹的回答非常好。我不禁补充说，这个问题不需要"循环"结构：

;; translate a string to a base-4 string.
(define (func n)
  (cond [(< n 4) (number->string n)]
        [else (string-append (func (quotient n 4))
                                   (number->string (modulo n 4)))]))