在我的代码中，我有一个子程序，它以第5列数组为参数，并使用一个局部变量，这是一个共享前4个索引的第4列数组。
我正试图找到一种更简洁的方式来表达中的大小声明
subroutine mysub(momentum)
complex, intent(in) :: momentum(:,:,:,:,:)
complex :: prefactor( &
& size(momentum,1), size(momentum,2), size(momentum,4) &
& size(momentum,5) )
...
end subroutine mysub
size声明的冗长会损害可读性，尤其是当变量名比这里更长时。
如果这是倍频程/matlab，我会通过编写来预先分配prefactor
prefactor = zeros(size(momentum)([1 2 4 5]))
Fortran 90支持类似的简洁功能吗？我知道它可以使用预处理器宏来解决，比如
#define XSIZE2(array,a,b) SIZE(array,a), SIZE(array,b)
#define XSIZE3(array,a,b,c) SIZE(array,a), SIZE(array,b), SIZE(array,c)
#define XSIZE4(array,a,b,c,d) SIZE(array,a), SIZE(array,b), SIZE(array,c), SIZE(array,d)
但引入这样的定义可能会对可读性造成更大的损害，而不是帮助。
Fortran 2008将mold说明符添加到allocate语句中。如果您可以访问支持此功能的编译器，您可以尝试
program main
implicit none
integer :: a(2,3,4,5,6)
integer, allocatable :: b(:,:,:,:)
print *, shape(a)
allocate(b, mold=a(:,:,:,:,1))
print *, shape(b)
end program main
此代码段适用于"英特尔Fortran 2016更新1"。
虽然这可能更像是一个注释，但定义一个这样的宏…怎么样。。。？
subroutine mysub(momentum)
complex, intent(in) :: momentum(:,:,:,:,:)
#define _(i) size( momentum, i )
complex :: prefactor( _(1), _(2), _(4), _(5) )
它也可以为不同的参数重复定义，例如：
subroutine mysub( momentum, coeff )
complex, intent(in) :: momentum(:,:,:,:,:), coeff(:,:,:)
#define _(i) size( momentum, i )
complex :: prefactor_momentum( _(1), _(2), _(4), _(5) )
#define _(i) size( coeff, i )
complex :: prefactor_coeff( _(1), _(3) )
如果可以使用可分配数组，我可以按如下方式分配它：
subroutine sub( momentum )
complex, intent(in) :: momentum(:,:,:,:,:)
complex, allocatable :: prefactor(:,:,:,:)
integer :: d( 5 )
d = shape( momentum )
allocate( prefactor( d(1), d(2), d(4), d(5) ) )
要获得几个不同参数的组合宏，尝试以下方法可能会很有用：
#define dim2(A,i1,i2) size(A,i1), size(A,i2)
#define dim3(A,i1,i2,i3) size(A,i1), size(A,i2), size(A,i3)
#define dim4(A,i1,i2,i3,i4) size(A,i1), size(A,i2), size(A,i3), size(A,i4)
#define _dims(A,_1,_2,_3,_4,NAME,...) NAME
#define getdims(A,...) _dims(A, __VA_ARGS__, dim4, dim3, dim2)(A,__VA_ARGS__)
subroutine mysub( momentum )
complex, intent(in) :: momentum(:,:,:,:,:)
complex :: prefactor2( getdims( momentum, 1, 5 ) )
complex :: prefactor3( getdims( momentum, 1, 3, 5 ) )
complex :: prefactor4( getdims( momentum, 1, 2, 4, 5 ) )
它（通过cpp -P）转换为
...
complex :: prefactor2( size(momentum,1), size(momentum,5) )
complex :: prefactor3( size(momentum,1), size(momentum,3), size(momentum,5) )
complex :: prefactor4( size(momentum,1), size(momentum,2), size(momentum,4), size(momentum,5) )
如果我关心这种简洁性，那么我会倾向于使用带有可分配局部变量的mold=说明符。这种语法在所有现代编译器中都得到了相当好的支持，应该可以很容易地融入构建过程。
然而，在评论这个答案时，你会说你更喜欢"派生形状"，而不是可分配的局部变量。让我们抛开这些在最终用途上几乎没有区别（有一些），探索一下这一方面。
"派生形状"是指一个显式的形状自动对象。对于这样的对象，每个列组的范围必须是规范表达式。您使用SIZE(momentum,1)等作为这些表达式。
语法上的困难在于，每个等级的范围都必须明确给出。因此，像这样更短的东西真的没有前景
complex prefactor(array_extents_spec) ! As an array, say.
但是，如果我们再次忽略Fortran 90的要求，我们还可以做其他事情。
考虑一个自动对象
complex, target :: prefactor_t(SIZE(momentum)/SIZE(momentum,3)) ! rank-1, of desired size
和阵列
integer extents(4)
extents = [SIZE(momentum,1), SIZE(momentum,2), SIZE(momentum,4), SIZE(momentum,5)]
我们可以有一个指针对象，其边界重新映射
complex, pointer :: prefactor(:,:,:,:)
prefactor(1:extents(1), 1:extents(2), 1:extents(3), 1:extents(4)) => prefactor_t
如果我们改为调用扩展数据块数组e，它可能会更整洁、甚至更短。
使用与自动对象范围使用数组相同的思想，我们可以使用block构造，该构造允许在可执行语句之后使用自动对象
complex, intent(in) :: momentum(:,:,:,;,:)
integer e(5)
e = SHAPE(momentum)
block
complex prefactor(e(1), e(2), e(4), e(5)) ! Automatic, of desired shape
end block
所有这一切的危险在于，仅仅为了让一个声明更整洁，就让事情变得更加模糊。总之，如果你想要比原来更整洁的东西，mold=真的是最好的选择。但我并不认为您的原始代码特别不清楚。在我看来，这里的其他建议都不比这更好，但请随意选择。