XSL组，并在顶部与特定项目进行排序

Question

下面我有一个带有事件列表的XML文件。我想实现的是将他们按城市与纽约始终处于领先地位。其他城市应该按名称进行排序，然后按日期排序。除了对其他城市进行分类之外，我还能做到这一切。

<Events>
  <Event id="1">
    <Title>Concert1</Title>
    <Date>2017-01-05 12:00</Date>
    <City>Seattle</City>
  </Event>
  <Event id="2">
    <Title>Concert2</Title>    
    <Date>2017-01-05 11:00</Date>
    <City>Los Angeles</City>
  </Event>
  <Event id="3">
    <Title>Concert3</Title>    
    <Date>2017-01-05 14:00</Date>
    <City>New York</City>
  </Event>
  <Event id="4">
    <Title>Concert4</Title>    
    <Date>2017-01-05 19:00</Date>
    <City>Austin</City>
  </Event>
    <Event id="5">
    <Title>Concert5</Title>    
    <Date>2017-01-05 15:00</Date>
    <City>New York</City>
  </Event>
  <Event id="6">
    <Title>Concert6</Title>    
    <Date>2017-01-05 12:00</Date>
    <City>Austin</City>
  </Event>
</Events>

和一个使用Muenchian分组的XLS（1.0）文件，按城市进行分组事件。同样，为了将纽约提取到列表的顶部，我进行了2个单独的面孔循环：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="UTF-8" indent="yes"/>
<xsl:key name="groups" match="City" use="."/>
<xsl:template match="/Events">
  <xsl:apply-templates select="Event/City[generate-id() = generate-id(key('groups', .)[1])]"/>
</xsl:template>
<!-- NEW YORK -->
<xsl:template match="City[text()='New York']">
  <xsl:variable name="currentGroup" select="."/> 
  <b><xsl:value-of select="$currentGroup"/></b><br/>
  <xsl:for-each select="key('groups', $currentGroup)">
  <xsl:sort select="../Date"/>  
  <i>+ <xsl:value-of select="../Date"/> <xsl:value-of select="../Title"/></i><br/>  
  </xsl:for-each>  
</xsl:template>
<!-- OTHER CITIES -->
<xsl:template match="City[text()!='New York']">
  <xsl:variable name="currentGroup" select="."/> 
  <b><xsl:value-of select="$currentGroup"/></b><br/>
  <xsl:for-each select="key('groups', $currentGroup)">
  <xsl:sort select="../Date"/>  
  <i>+ <xsl:value-of select="../Date"/> <xsl:value-of select="../Title"/></i><br/>  
  </xsl:for-each>  
</xsl:template>
</xsl:stylesheet>

当前"其他城市"为输入顺序。我如何对XML进行分组和排序，以使HTML结果就是这样：

New York 
+ 14:00 Concert3 
+ 15:00 Concert5
Austin
+ 12:00 Concert6
+ 19:00 Concert4
Los Angeles
+ 11:00 Concert2
Seattle
+ 12:00 Concert1

Answer 1

我不确定为什么您发布的代码会首先输出"纽约"事件，但是对于

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html" encoding="UTF-8" indent="yes"/>
<xsl:key name="groups" match="City" use="."/>
<xsl:template match="/Events">
  <xsl:apply-templates select="key('groups', 'New York')[1]"/>
  <xsl:apply-templates select="Event/City[generate-id() = generate-id(key('groups', .)[1])][. != 'New York']">
      <xsl:sort select="."/>
  </xsl:apply-templates>
</xsl:template>
<xsl:template match="City">
  <xsl:variable name="currentGroup" select="."/> 
  <b><xsl:value-of select="$currentGroup"/></b><br/>
  <xsl:for-each select="key('groups', $currentGroup)">
  <xsl:sort select="../Date"/>  
  <i>+ <xsl:value-of select="../Date"/> <xsl:value-of select="../Title"/></i><br/>  
  </xsl:for-each>  
</xsl:template>

</xsl:stylesheet>