如何使xsl标记化工作

Question

我有一个巨大的xsl文件，但我使用"tokenize"通过逗号分隔的字符串进行解析的部分引发了一个错误。为了简单起见，我将其分解为仅测试标记化部分，似乎无法取得任何进展。我一直得到以下错误：

应为表达式。标记化（-->[<--text]，'，'）

我试着使用其他帖子中分享的一些示例xsl，但始终未能成功。我很难理解为什么下面的xsl代码无效。这似乎不是很简单，但我想我错过了一些简单的东西。如果能帮我找到正确的方向，我们将不胜感激。

XSL:

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/root">
<xsl:for-each select="tokenize([text],',')"/>
<items>
<item>
<xsl:value-of select="."/>
</item>
</items>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>

XML:

<?xml-stylesheet type="text/xsl" href="simple.xsl"?>
<root>
<text>Item1, Item2, Item3</text>
</root>

我期望XML输出如下：

<items>
<item>Item1</item>
<item>Item2</item>
<item>Item3</item>
</items>

谢谢！

Answer 1

我看到了4个错误：

1. 您正在1.0样式表中使用tokenize()。您需要将版本更改为2.0，并使用2.0处理器。如果您使用web浏览器根据xml-stylesheet处理指令进行转换，那么您可能没有使用2.0处理器。

2. 标记化（[text]）的第一个参数无效。只需使用text。

3. 您过早地关闭了xsl:for-each。

4. 您为每个项目输出一个<items>。将<items>置于xsl:for-each之外。

更改示例：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/root">
        <items>
            <xsl:for-each select="tokenize(text,',')">
                <item>
                    <xsl:value-of select="."/>
                </item>
            </xsl:for-each>
        </items>
    </xsl:template>
</xsl:stylesheet>

为了使用2.0处理器真正获得您想要的输出，我还建议使用xsl:output和normalize-space():

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:template match="/root">
        <items>
            <xsl:for-each select="tokenize(text,',')">
                <item>
                    <xsl:value-of select="normalize-space(.)"/>
                </item>
            </xsl:for-each>
        </items>
    </xsl:template>
</xsl:stylesheet>

Answer 2

正如DevNull所说，tokenize（）是一个XSLT2.0函数。但是，如果您的处理器支持EXSLT，则use可以使用str:tokenze（）函数。否则，您将需要使用递归来拆分逗号分隔的值，如。。。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />
<xsl:template match="/">
 <items>
   <xsl:apply-templates select="root/text"/>
 </items>
</xsl:template>
<xsl:template match="text">
 <xsl:call-template name="tokenize"> 
   <xsl:with-param name="csv" select="." /> 
 </xsl:call-template>    
</xsl:template>
<xsl:template name="tokenize">
 <xsl:param name="csv" />
  <xsl:variable name="first-item" select="normalize-space( 
    substring-before( concat( $csv, ','), ','))" /> 
 <xsl:if test="$first-item">
  <item>
   <xsl:value-of select="$first-item" /> 
  </item>  
  <xsl:call-template name="tokenize"> 
   <xsl:with-param name="csv" select="substring-after($csv,',')" /> 
  </xsl:call-template>    
 </xsl:if>  
</xsl:template>
</xsl:stylesheet>