build.如何为不同的源代码构建项目在 gradle 中的兼容性和目标兼容性

Question

我目前在gradle文件中的配置是

sourceCompatibility = 1.7
targetCompatibility = 1.7

此规范使我的项目特定于 Java 1.7。

我的要求是我应该能够为不同的java版本构建我的项目，例如java 1.7和java 1.8

PS：就像在gradle中构建配置文件一样，我们可以在其中指定不同的java版本。

Answer 1

Gradle使用它在PATH或JAVA_HOME中找到的任何JDK。因此，如果您删除 sourceCompatibility 和 targetCompatibility ，它应该使用运行该项目的机器上使用的 Java 版本构建项目。当然，这确实意味着你不应该在代码中使用像lambda这样的结构，否则Java 7上的编译将失败。

您还应该知道，从 Gradle 5 开始，对 Java 7 的支持将被放弃，它将仅在 Java 8(或更高版本(上运行。

另一种方法是在运行时指定 JDK，请参阅此链接

如果要同时为多个 Java 版本进行构建，可以使用如下所示的内容：

task compile7(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = 1.7
   targetCompatibility = 1.7
   destinationDir = file('build/java7')
}
task jar7(type: Jar, dependsOn: compile7) {
   from('build/java7')
   archiveName = 'project-JDK7.jar'
   destinationDir = file('build/jars')
}
task compile8(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = 1.8
   targetCompatibility = 1.8
   destinationDir = file('build/java8')
}
task jar8(type: Jar, dependsOn: compile8) {
   from('build/java8')
   archiveName = 'project-JDK8.jar'
   destinationDir = file('build/jars')
}

您可以调用gradle jar7 jar8为所需的两个 Java 版本构建 jar。当然，上面的代码可以改进以参数化操作，如下所示：

ext.javaVer = project.hasProperty('javaVer') ? project.getProperty('javaVer') : '1.7'
task compileJ(type: JavaCompile) {
   source = fileTree(dir: 'src', include: '**/*.java')
   classpath = sourceSets.main.compileClasspath
   sourceCompatibility = javaVer
   targetCompatibility = javaVer
   destinationDir = file('build/' + javaVer)
}
task jarJ(type: Jar, dependsOn: compileJ) {
   from('build/' + javaVer)
   archiveName = 'project-' + javaVer + '.jar'
   destinationDir = file('build/jars')
}

使用此格式，您将调用 gradle jarJ -P javaVer=1.8 和 gradle jarJ 来构建 Java 8 和 Java 7。

Answer 2

这就是我解决它的方式

ext.javaVer = project.hasProperty('javaVer') ? project.getProperty('javaVer') : '1.7'
sourceCompatibility = javaVer
targetCompatibility = javaVer

在建设项目时

gradle build -P javaVer=1.8