枫树:具有两个变量的线性系统图

Question

我的 Maple 项目有问题。我想绘制三个线性方程，我正在使用LinearSystemPlot函数。但我也想让它更具交互性，所以我使用Explore函数。我试图在互联网上找到一些帮助，但找不到任何相关的东西。这就是我能够做的

restart;
with(Student[LinearAlgebra]);
with(LinearAlgebra, SubMatrix);
s := [-u*z+x-2*y = -2, x+y-2*z = 7, 2*x+y-3*z = -v];
Explore(LinearSystemPlot(s, colors = [plum, maroon, pink]), parameters = [u = -10 .. 10, v = -20 .. 20], placement = bottom);

当我执行它时，我得到正确的图表，下面有滑块。问题是，当我想更改u或v的值时，出现此错误

(在学生：-线性代数：-线性系统图(系统没有 包含 2 或 3 个变量

标题为"滑块"的组件滑块中出现错误

我正在使用Maple2015，如果它很重要的话。

感谢您的任何帮助。

Answer 1

以下任何一种方式都应该适用于您的 Maple 2015。

第一种方法是在对LinearSystemPlot命令的调用中显式输入列表。这种方式需要在命令中显式键入列表，但探索可能会在重新启动后立即起作用。

下一对探索函数调用，以尊重地H和F。其中第一个在方法上类似于?examples,Explore帮助页面上的一些示例。

请注意，在第三种和第四种方式中，我使用单左引号(又名uneval引号，以延迟评估(。您需要像我一样键入它们，并使用正确的引号。

"探索"命令的第一个参数具有特殊的评估规则，我使用uneval引号是允许"探索"查看分配给s的列表(而不仅仅是名称s(。

restart;
Explore( Student:-LinearAlgebra:-LinearSystemPlot(
           [-u*z+x-2*y = -2, x+y-2*z = 7, 2*x+y-3*z = -v],
           colors=[plum,maroon,pink] ),
         parameters = [u = -10 .. 10.0, v = -20 .. 20.0] );
restart;
H :=proc(U,V)
      uses Student:-LinearAlgebra;
      LinearSystemPlot( [-U*z+x-2*y = -2, x+y-2*z = 7, 2*x+y-3*z = -V],
                        colors=[plum,maroon,pink] );
end proc:
Explore( H(u,v),
         parameters = [u = -10 .. 10.0, v = -20 .. 20.0] );
restart;
s := [-u*z+x-2*y = -2, x+y-2*z = 7, 2*x+y-3*z = -v]:
F := unapply( 'Student:-LinearAlgebra:-LinearSystemPlot'(s, colors=[plum,maroon,pink]),
              [u,v] ):
Explore (F(u,v),
         parameters=[u=-10 .. 10.0, v=-20 .. 20.0] );
restart;
s := [-u*z+x-2*y = -2, x+y-2*z = 7, 2*x+y-3*z = -v]:
eval( 'Explore'('Student:-LinearAlgebra:-LinearSystemPlot'(s, colors=[plum,maroon,pink]),
               parameters=[u=-10 .. 10.0, v=-20 .. 20.0] ) );

这是上面第二种方式的变体。通过这种方式，您可以调整列表s并继续探索，而无需再次调用Explore。

restart;
s := [-u*z+x-2*y = -2, x+y-2*z = 7, 2*x+y-3*z = -v]:
H :=proc(U,V)
      global s;
      uses Student:-LinearAlgebra;
      LinearSystemPlot( eval(s, [u=U, v=V]),
                        colors=[plum,maroon,pink] );
end proc:
Explore( H(u,v),
         parameters = [u = -10 .. 10.0, v = -20 .. 20.0] );

您可能希望尝试在绘图上使用固定视图(使用 LinearSystemPlot 命令的 view 选项(。