在Terraform中创建Bigquery景色

Question

我在BQ中有一堆表，这些表基于Terraform中的Google_bigquery_table资源。我需要为其中一个表创建一个视图，但是，我不想创建另一个Terraform资源来避免代码重复。这就是我的资源现在的样子：

resource "google_bigquery_table" "default" {

dataset_id = "${var.dataset_id}"
  table_id   = "${var.table_id}"
  time_partitioning {
    type = "DAY" //Hardcoded because this is the only supported value
    field = "${var.time_partitioning_field}"
  }
  view {
    query = "${var.query}"
    use_legacy_sql = "${var.use_legacy_sql}"
  }
  schema =   "${file(var.schema)}"
}

相关视图变量是：

variable "query" {
  type = "string"
  default = ""
}
variable "use_legacy_sql" {
  type = "string"
  default = "false"
}

我将查询变量设置为一个空字符串，因为我不希望其他任何表具有视图。

最后，这是包含视图的表模块：

module "myTable-editedView-bigquery-table"{
  source  = "./../../modules/google-bigquery-table"
  version = "0.1"
  schema = "${var.myTable_schema}"
  dataset_id   = "${module.myDataset-bigquery-dataset.dataset_id[0]}"
  table_id     = "${var.myTable_editedView_table_id}"
  query = <<SQL
      SELECT col1 ,  col2, col3, col4, col5
      FROM `myProject.myDataset.myTable`
      SQL
  time_partitioning_field = "${var.time_partitioning_field}"
  is_ready      = "${module.myDataset-bigquery-dataset.is_complete}"
  is_ready      = "${module.myTable-bigquery-table.is_complete}"
}

我的其他表格的格式类似，除了我没有提供查询变量/值，因为我不希望它们具有视图。

计划似乎已经很好，但是Terraform应用的每个现有表都会出现错误，声称需要查询查询。我想这是有道理的，因为我为每个表定义了一个查询变量，但是我认为它将默认为空字符串而不是创建视图。我应该从这里采取什么方法？

Answer 1

我认为您只需要一个动态块，以便在需要时添加view块：

resource "google_bigquery_table" "default" {
  dataset_id = var.dataset_id
  table_id   = var.table_id
    
  time_partitioning {
    type = "DAY" //Hardcoded because this is the only supported value
    field = var.time_partitioning_field
  }
  
  dynamic "view" {
    for_each = var.query == null ? [] : [var.query]
    content {
      query = view.value
      use_legacy_sql = var.use_legacy_sql
    }
  }
    
  schema =   file(var.schema)
}
variable "query" {
  type = "string"
  default = null
}
variable "use_legacy_sql" {
  type = "string"
  default = "false"
}

请注意，您也不需要到处使用"${var.var_name}"，这与var.var_name相同。我认为在较早的Terraform版本中并非如此。