SAS 给定一个开始和结束日期，我需要知道前 35 天后每个 30 天周期的日期

Question

我得到了2个日期，一个开始日期和一个结束日期。

我想知道第一个 35 天期限的日期，然后是随后的每个 30 天周期。

我有;

start       end
22-Jun-15   22-Oct-15
9-Jan-15    15-May-15

我想要;

start       end         tik1        tik2        tik3        tik4
22-Jun-15   22-Oct-15   27-Jul-15   26-Aug-15   25-Sep-15   
9-Jan-15    15-May-15   13-Feb-15   15-Mar-15   14-Apr-15   14-May-15

我对日期计算很好，但我真正的问题是创建一个变量并增加其名称。我决定包括我的整个问题，因为我认为在其上下文中可能更容易解释。

Answer 1

您可以通过以下逻辑解决问题：

1) 确定要添加的列数。

2) 根据要求计算列的值

data test;
input start end;
informat start date9. end date9.;
format start date9. end date9.;
datalines;
22-Jun-15 22-Oct-15
09-Jan-15 15-May-15
;
run;
/*******Determining number of columns*******/
data noc_cal;
set test;
no_of_col = floor((end-start)/30);
run;
proc sql;
select max(no_of_col) into: number_of_columns from noc_cal;
run;
/*******Making an array where 1st iteration(tik1) is increased by 35days whereas others are incremented by 30days*******/
data test1;
set test;
array tik tik1-tik%sysfunc(COMPRESS(&number_of_columns.));
format tik: date9.;
tik1 = intnx('DAYS',START,35);
do i= 2 to %sysfunc(COMPRESS(&number_of_columns.));
tik[i]= intnx('DAYS',tik[i-1],30);
if tik[i] > end then tik[i]=.;
end; 
drop i;
run;

替代方式(如果您不想使用 proc sql)

data test;
input start end;
informat start date9. end date9.;
format start date9. end date9.;
datalines;
22-Jun-15 22-Oct-15
09-Jan-15 15-May-15
;
run;
/*******Determining number of columns*******/
data noc_cal;
set test;
no_of_col = floor((end-start)/30);
run;
proc sort data=noc_cal;
by no_of_col;
run;
data _null_;
set noc_cal;
by no_of_col;
if last.no_of_col;
call symputx('number_of_columns',no_of_col);
run;
/*******Making an array where 1st iteration(tik1) is increased by 35days whereas others are incremented by 30days*******/
data test1;
set test;
array tik tik1-tik%sysfunc(COMPRESS(&number_of_columns.));
format tik: date9.;
tik1 = intnx('DAYS',START,35);
do i= 2 to %sysfunc(COMPRESS(&number_of_columns.));
tik[i]= intnx('DAYS',tik[i-1],30);
if tik[i] > end then tik[i]=.;
end; 
drop i;
run;

我的输出：

> **start   |end        |tik1     | tik2     |tik3     |tik4**
> 22Jun2015 |22Oct2015  |27Jul2015| 26Aug2015|25Sep2015|    
> 09Jan2015 |15May2015  |13Feb2015| 15Mar2015|14Apr2015|14May2015

Answer 2

我倾向于喜欢长垂直结构。 我会这样处理它：

data want;
set have;
tik=start+35;
do while(tik<=end);
output;
tik=tik+30;
end;
format tik mmddyy10.;
run;

如果你真的需要它的范围，你可以在第二步中转置该数据集。