迁移Qt项目文件到CMake

Question

我正在尝试迁移一个QtProject文件，正是来自https://github.com/gamecreature/QtAwesome的QtAwesome库

我要迁移的项目文件是:

TARGET = QtAwesome
TEMPLATE = lib
CONFIG += staticlib c++11
SOURCES += QtAwesome.cpp
HEADERS += QtAwesome.h
isEmpty(PREFIX) {
    unix {
        PREFIX = /usr
    } else {
        PREFIX = $$[QT_INSTALL_PREFIX]
    }
}
install_headers.files = QtAwesome.h
install_headers.path = $$PREFIX/include
target.path = $$PREFIX/lib
INSTALLS += install_headers target
RESOURCES += 
    QtAwesome.qrc

我的翻译是:

cmake_minimum_required(VERSION 2.8.11)
project(QtAwesome)
file(GLOB_RECURSE CODE_FILES QtAwesome.cpp)
find_package (Qt5Core REQUIRED)
ADD_DEFINITIONS(-DQTAWESOME_LIBRARY)
qt5_add_resources(RESOURCE_FILES QtAwesome.qrc)
qt5_wrap_cpp(LIB_HEADER_MOC QtAwesome.h)
add_library(QtAwesome STATIC QtAwesome.cpp QtAwesome.h)
target_link_libraries(QtAwesome
    Qt5::Widgets
)

可以编译，但是当我尝试使用这个构建的库时，我得到以下错误:

[100%] Linking CXX executable MyProject.exe
QtAwesome.lib(QtAwesome.cpp.obj) : error LNK2019: unresolved external symbol "int __cdecl qInitResources_QtAwesome(void)" (?qInitResources_QtAwesome@@YAHXZ) referenced in function "public: bool __cdecl QtAwesome::initFontAwesome(void)" (?initFontAwesome@QtAwesome@@QEAA_NXZ)
MyProject.exe : fatal error LNK1120: 1 unresolved externals

Answer 1

在你的cmake项目中有几个问题:

file(GLOB_RECURSE CODE_FILES QtAwesome.cpp)

你没有在任何地方使用CODE_FILES。此外，将glob与文件名一起使用而不是文件模式是没有意义的，并且不应该使用glob来收集源代码(请参阅文档)。

ADD_DEFINITIONS(-DQTAWESOME_LIBRARY)

QTAWESOME_LIBRARY在QtAwesome代码的任何地方都没有使用(参见存储库中的搜索结果)。无论如何，如果你必须添加定义，你可以考虑target_compile_definitions代替。

qt5_add_resources(RESOURCE_FILES QtAwesome.qrc)
qt5_wrap_cpp(LIB_HEADER_MOC QtAwesome.h)

RESOURCE_FILES和LIB_HEADER_MOC在调用add_library时不添加到源:资源和moc文件不会被编译到您的库中(我猜这是您这里的主要问题)。您可以考虑使用CMAKE_AUTOMOC和CMAKE_AUTORCC。

find_package (Qt5Core REQUIRED)
# ...
target_link_libraries(QtAwesome
    Qt5::Widgets
)

您正在链接Widgets模块，而只寻找Core模块。

在你的cmake项目中你不需要c++ 11标准:你可能需要使用CMAKE_CXX_STANDARD，或者，如果你知道需要标准的哪一部分，使用编译功能。

清理后，您的cmake项目可能看起来像这样:

cmake_minimum_required(VERSION 2.8.11)
project(QtAwesome)
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)
find_package(Qt5 REQUIRED COMPONENTS Widgets)
add_library(QtAwesome STATIC
    QtAwesome.cpp
    QtAwesome.h
    QtAwesome.qrc
)
target_link_libraries(QtAwesome
    Qt5::Widgets
)

Answer 2

我发现这很有帮助https://github.com/qt/qtbase/blob/dev/util/cmake/run_pro2cmake.py

我能够将qmake (.pro)项目转换为cmake。它生成了一个工作的CMakeLists.txt