XSL:向所有元素添加一个新元素

Question

我是XSL/XSLT的新手。我正在尝试向这个xml:的所有users元素添加一个新元素（数据源）

    <?xml version="1.0" encoding="UTF-8" standalone="no"?>
<users>
    <user id="1">
        <repo>r1</repo>
        <home>h1</home>
    </user>
    <user id="2">
        <repo>r2</repo>
        <home>h2</home>
    </user>
    <user id="3">
        <repo>r3</repo>
        <home>h3</home>
    </user>
    <user id="4">
        <repo>r4</repo>
        <home>h4</home>
    </user>
    <user id="5">
        <repo>r5</repo>
        <home>h5</home>
    </user>
</users>

我正在使用这个XSL脚本：

    <?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" cdata-section-elements="configXml"/>
    <!-- Copy everything -->
    <xsl:template match="node()">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="/users/user[*]">
        <xsl:copy>
            <xsl:apply-templates/>
            <xsl:element name="datasources"></xsl:element>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

问题是，在最终结果中，所有用户的id都消失了：

<users>
<user>
    <repo>r1</repo>
    <home>h1</home>
    <datasources/>
</user>
<user>
    <repo>r2</repo>
    <home>h2</home>
    <datasources/>
</user>
    <user>
    <repo>r3</repo>
    <home>h3</home>
    <datasources/>
</user>
    <user>
    <repo>r4</repo>
    <home>h4</home>
    <datasources/>
</user>
    <user>
    <repo>r5</repo>
    <home>h5</home>
    <datasources/>
</user>

如何在输出中保留用户id？

Answer 1

您的复制所有模板需要是：

<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

请参见如何按原样复制所有内容并仅删除特定元素。

发生的情况是，您的第二个模板与<user>元素匹配，但<apply-templates/>不会在属性上使用第一个模板，因为它们与node() 不匹配

正如Ian Roberts所指出的，您还需要在第二个模板的<xsl:apply-templates/>中显式选择@*|node()，以便也处理属性——在这种情况下，它们将被修改后的第一个模板拾取。

因此，完整的解决方案是：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" cdata-section-elements="configXml"/>
    <!-- Copy everything -->
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="/users/user[*]">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
            <xsl:element name="datasources"></xsl:element>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Answer 2

属性不会被复制，因为您没有复制它们-按照其他模板的模式，在您的/users/user[*]模板中，您需要添加

<xsl:copy-of select="@*"/>

作为CCD_ 7中在将模板应用于子对象之前的第一件事。