使用 Spock 在不同的测试环境中运行测试

Question

我目前正在使用 REST Client 和 Spock 编写 REST API 测试。我希望能够在不同的测试环境中运行我的测试。我的测试数据因测试环境而异，因此需要为每个环境使用和指定不同的输入数据。对于下面的示例测试

class MathSpec extends Specification {
def "maximum of two numbers"() {
expect:
Math.max(a, b) == c
where:
a | b || c
1 | 3 || 3
}
}

我可以为每个环境指定不同的数据表吗？

class MathSpec extends Specification {
def "maximum of two numbers"() {
expect:
Math.max(a, b) == c
where:
@TEST 
a | b || c
1 | 3 || 3
@PROD
a | b || c
4 | 5 || 6
}
}

如果没有，解决此问题的最佳方法是什么？谢谢。

Answer 1

我想到的实现您期望的最简单方法是在根据某些条件(例如执行环境)运行测试方法之前准备数据，然后在测试中使用此预定义数据。请考虑以下示例：

import spock.lang.Shared
import spock.lang.Specification
import spock.lang.Unroll
class EnvBasedDataSpec extends Specification {
@Shared
static Map data = [:]
def setupSpec() {
/* If you want to pick variable from env variables, use:
* System.getenv().getOrDefault('execution.environment', 'test')
*
* If you want to provide variable like -Dexecution.environment=test, use:
* System.getProperty('execution.environment', 'test')
*/
def executionEnvironment = System.getProperty('execution.environment', 'test')
switch (executionEnvironment) {
case 'test':
data = [a: 1, b: 3, c: 3]
break
case 'prod':
data = [a: 2, b: 4, c: 4]
break
}
}
@Unroll
def "maximum of two numbers (#a, #b) == #c"() {
expect:
Math.max(a, b) == c
where:
a       | b         || c
data.a  | data.b    || data.c
}
}

在此示例中，我们准备共享data，用于保存我们将在测试中使用的值。在这里，我们期望执行环境信息将作为

-Dexecution.environment=value 

属性(或者，您可以使用 env 变量传递相同的信息)。在此示例中，如果缺少给定属性，我们也使用默认值 - 在这种情况下test(如果您忘记指定执行环境变量，它将防止测试失败)。

替代方法：@IgnoreIf条件执行

Spock 支持条件执行。看看如果我们使用@IgnoreIf方法，相同的测试会是什么样子：

import spock.lang.IgnoreIf
import spock.lang.Specification
class AlternativeEnvBasedDataSpec extends Specification {
@IgnoreIf({ System.getProperty('execution.environment') == 'prod' })
def "maximum of two numbers (test)"() {
expect:
Math.max(a, b) == c
where:
a  | b  || c
1  | 3  || 3
}
@IgnoreIf({ System.getProperty('execution.environment') == 'test' })
def "maximum of two numbers (prod)"() {
expect:
Math.max(a, b) == c
where:
a  | b  || c
2  | 4  || 4
}
}

不幸的是，这种方法需要大量的重复：你必须复制测试方法，并且不能重复使用相同的名称(编译器不允许这样做)。它很容易出错 - 您必须注意将相同的测试主体放在所有应该测试相同内容但具有不同数据的方法上。另一件事是，如果您引入第 3 个环境，则必须修改传递给@IgnoreIf的条件 - 在这种情况下，您将指定如下内容：

@IgnoreIf({ !(System.getProperty('execution.environment') in ['staging', 'prod']) })

我想你会看到它开始有多大问题。

Answer 2

> Spock 有多变量数据管道来处理这个问题。您可以将"逻辑"移动到数据驱动的方法。

class MathSpec extends Specification {
def "maximum of two numbers"(int a, int b, int c) {
expect:
Math.max(a, b) == c
where:
[a, b, c] << getData()
}
def getData() {
if (System.getProperty("Staging"))
[ [1, 3, 3] ]
else
[ [3, 5, 5] ]
}
}

在您的情况下，我会使用抽象getData()方法。
我将在两个不同的类中实现getData()MathProductionSpec和MathStagingSpec
我会使用 spock 注释根据您的环境执行。

例：

abstract class MathSpec extends Specification {
def "maximum of two numbers"(int a, int b, int c) {
expect:
Math.max(a, b) == c
where:
[a, b, c] << getData()
}
def abstract getData()
}

@Production
class MathProductionSpec extends MathSpec {
def getData() {
[ [4, 2, 4] ]
}
}

@Staging
class MathStagingSpec extends MathSpec {
def getData() {
[ [1, 3, 3] ]
}
}