使用Xquery向现有XML中的元素添加属性

Question

我需要使用XQuery向响应XML的元素添加一个属性。以以下XML作为输入，

<xyz:RootNode xmlns:abc="url1" xmlns:xyz="url2">
  <abc:OtherNodes/>
  <abc:messageHeader att1="val1" att2="val2">
       <abc:childNodes/>  
  </abc:messageHeader>
  <abc:OtherNodes/>
</xyz:RootNode>

需要一个Xquery，添加一个值为newVal的属性newAtt，并给出

<xyz:RootNode xmlns:abc="url1" xmlns:xyz="url2">
   <abc:OtherNodes/>
   <abc:messageHeader att1="val1" att2="val2" newAtt="newVal">
       <abc:childNodes/>  
  </abc:messageHeader>
  <abc:OtherNodes>
</xyz:RootNode>

每次消息头的属性数量都可能发生变化。因此，查询应该添加一个新属性以及所有现有属性，并返回整个文档。

Answer 1

尝试以下操作：

xquery version "3.0";
module namespace foo="http://exist-db.org/apps/ns/foo";
declare function foo:process-node($node as node()?, $model as map()) {
    if ($node) then 
    typeswitch($node) 
        case text() return $node
        case element(messageHeader) return foo:messageHeader($node, $model)
        default return element { $node/name() } 
                               { $node/@*, foo:recurse($node, $model) }
    else () 
};
declare function foo:recurse($node as node()?, $model as map()) as item()* {
    if ($node) 
    then 
        for $cnode in $node/node() 
        return foo:process-node($cnode, $model) 
    else ()
};
declare function foo:messageHeader($node as node(), $model as map()) {
element { $node/name() } 
        { $node/@*, 
          attribute { 'newAtt' } { 'newVal' },
          foo:recurse($node, $model)
        }
};

然后在RootNode 上调用foo:process节点

Answer 2

您总是可以重复使用XSLT这样的轮子。尤其是如果您希望将代码中的风险降至最低。

eXist支持XSL转换，下面是一个如何运行XSLT转换以完成您想要的工作的示例：

xquery version "3.0";
declare function local:add-attribute($input as node()?, $attributeName as xs:string, $attributeValue as xs:string?) {
    let $xslt := <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template xmlns:abc="url1" match="abc:messageHeader">
        <xsl:copy>
            <xsl:apply-templates select="@*"/>
            <xsl:attribute name="{$attributeName}">{$attributeValue}</xsl:attribute>
            <xsl:apply-templates select="node()"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>
return transform:transform($input, $xslt, ())
};
let $input := <xyz:RootNode xmlns:abc="url1" xmlns:xyz="url2">
  <abc:OtherNodes/>
  <abc:messageHeader att1="val1" att2="val2">
       <abc:childNodes/>  
  </abc:messageHeader>
  <abc:OtherNodes/>
</xyz:RootNode>
return local:add-attribute($input, "hey", "bam")

如果您想将XSLT放入自己的文件中，也可以使用$parameters属性。将使事情变得更加可测试和模块化。