XSLT对每个元素的设置值进行检查值

Question

我不是XSLT中的专家。我需要检查所有"代码"值，根据以下规则设置状态代码。

1. 如果所有代码值均为200，则将状态代码设置为200，而推理将成功定为成功
2. 如果所有代码值均为200或204，则将状态代码设置为200，而推理形式为所有原因的convatnatiopn，这些代码具有200。
3. 如果至少一个代码包含200和204以外的其他值，则将状态代码设置为503，而推理的态度为所有原因，这些原因具有200。
以外的代码。

我尝试了几种将所有代码值存储在一个变量中的方法，并且Execeute包含具有上述条件的函数，以及创建代码变量和存储值，然后检查字符串长度。但是我没有取得任何成功。

，如果可能的话，我正在寻找一些更通用的方式，因为此要求是复杂XSLT及以下的一部分，只是要求的一个例子。一旦获得以下代码的逻辑，我应该能够在复杂的XSLT中拟合逻辑。

我还试图在答案中搜索，但无法获得任何适合此要求的解决方案。

我正在寻找XSLT 1.0中的解决方案，因为XSLT的其他部分是用XSLT 1.0

编写的

输入 -

            <root>
                <Node1>
                        <code>200</code>
                        <reason>Success</reason>
                </Node1>
                <Node1>
                        <code>200</code>
                        <reason>Success</reason>
                </Node1>
                <Node1>
                        <code>204</code>
                        <reason>Business Error</reason>
                </Node1>
                <Node1>
                        <code>500</code>
                        <reason>Tech Error</reason>
                </Node1>
                <Node1>
                        <code>200</code>
                        <reason>Success</reason>
                </Node1>
            </root>

输出 -

            <root>
            <output>
                <statuscode></statuscode>
                <reasonphrase></reasonphrase>
            </output>
            </root>

谢谢。

Answer 1

尝试以此作为您的起点：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/root">
    <xsl:copy>
        <output>
            <xsl:choose>
                <xsl:when test="not(Node1[code!=200])">
                    <!-- all code values are 200 -->
                    <statuscode>200</statuscode>
                    <reasonphrase>success</reasonphrase>
                </xsl:when>
                <xsl:when test="not(Node1[code!=200 and code!=204])">
                    <!-- all code values are either 200 or 204 -->
                    <statuscode>200</statuscode>
                    <reasonphrase>
                        <xsl:for-each select="Node1[code!=200]">
                            <xsl:value-of select="code"/>
                            <xsl:if test="position()!=last()">
                                <xsl:text> </xsl:text>
                            </xsl:if>
                        </xsl:for-each>  
                    </reasonphrase>
                </xsl:when>
                <xsl:otherwise>
                    <statuscode>503</statuscode>
                    <reasonphrase>
                        <xsl:for-each select="Node1[code!=200]">
                            <xsl:value-of select="code"/>
                            <xsl:if test="position()!=last()">
                                <xsl:text> </xsl:text>
                            </xsl:if>
                        </xsl:for-each>  
                    </reasonphrase>
                </xsl:otherwise>
            </xsl:choose>
        </output>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

---

请注意，这可以简化以消除重复代码 - 但这里的目的是显示如何测试给定条件。