我试图使用以下事实和规则（简化）找到希腊神话缪斯女神的祖先：
/* parent(A, B) - A is the parent of B */
parent(zeus, calliope).
parent(zeus, clio).
parent(zeus, melpomene).
parent(zeus, euterpe).
parent(zeus, erato).
parent(zeus, terpsichore).
parent(zeus, urania).
parent(zeus, thalia).
parent(zeus, polymnia).
parent(mnemosyne, calliope).
parent(mnemosyne, clio).
parent(mnemosyne, melpomene).
parent(mnemosyne, euterpe).
parent(mnemosyne, erato).
parent(mnemosyne, terpsichore).
parent(mnemosyne, urania).
parent(mnemosyne, thalia).
parent(mnemosyne, polymnia).
parent(kronos, zeus).
parent(rheia, zeus).
parent(oranos, kronos).
parent(gaia, oranos).
muse和祖先规则定义为：
/* A is a Muse if A's parents are Zeus and Mnemosyne */
muse(A):- parent(zeus, A), parent(mnemosyne, A).
/* A is the ancestor of B if A is the parent of B */
ancestor(A, B):- parent(A, B).
/* A is an ancestor of C if A is the parent of B and B is the ancestor of C */
ancestor(A, C):- parent(A, B), ancestor(B, C).
我想基本上执行以下操作：
/* Get the set of ancestors A of muses B and store in Z*/
setof(A, ancestor(A, muse(B)), Z).
这不起作用，并返回false .我尝试过的另一个变体：
findall(B, muse(B), Muses),
setof(A, ancestor(A, Muses), Z).
但鉴于我有更多的parent事实，它只是遍历了每一个可能的ancestor袋子。
我尝试的最后一个变体：
setof(A, ancestor(A, member(X, muse(X)), Z).
但错误与：
ERROR: Syntax error: Operator expected
ERROR: setof(A, ancestor(A, member(X, muse(X)), Z)
ERROR: ** here **
ERROR: .
这是有道理的。
我希望能够编写结果，例如：
write('The Muses ancestors are: '), write(MuseAncestors), nl.
我做错了什么？
要将复合目标传递给以目标为参数的谓词，只需将其放在括号中：
setof(X, ( G1, G2 ), Xs).
至于你的复合目标：也许最好问一下：
谁是缪斯的祖先？
?- muse(M), ancestor(A, M).
你需要一个目标的组合。任何介绍性的Prolog文本都应该解释连词的含义以及为什么ancestor(A, muse(M))不是你的意思。
请记住，如果您编写：
?- setof(A, ( muse(M), ancestor(A, M) ), As).
你M留下一个自由变量，你将得到一组解决方案，用于此变量的每个可能的绑定。为了避免这种情况，你可以明确地告诉Prolog不要尝试绑定它：
?- setof(A, M^( muse(M), ancestor(A, M) ), As).
As = [gaia, kronos, mnemosyne, oranos, rheia, zeus].