CMake:如何将额外的编译定义附加到依赖的 lib 构建中

Question

我有一个共享库，libShared，用于构建不同的可执行文件。我要做的是基于构建可执行文件，将其他编译定义添加到共享库。

CMakeLists.txt在我的lib文件夹中：

...
add_definition(-Dfoo -Dbar)
add_library(shared ${SOURCES})

exe1文件夹中的CMakeLists.txt：

...
add_executable(exe1 ${SOUCE_FILES})
add_dependencies(exe1 shared)
# <How Do I append -DForExe1 compile definition to shared>?
target_link_libraries(exe1 shared)

exe2文件夹中的CMakeLists.txt：

...
add_executable(exe2 ${SOURCES})
add_dependentcies(exe2 shared)
# <How Do I append -DForExe2 compile definition to shared>?
target_link_libraries(exe2 shared)

如何在 CMake 中执行此操作？

Answer 1

不能有具有不同编译定义的单个库目标。

不同的编译

定义意味着不同的编译操作，导致不同的对象文件。但这会破坏库的概念，即库已经编译(并且在共享库的情况下是链接的(。

---

如果为库设置了少量可能的编译定义，则可以为每个集合定义库目标：

# Common definitions for any library.
add_definition(-Dfoo -Dbar)
# Common sources for any library
set(LIB_SOURCES ...)
# The library specialized for exe1.
add_library(lib_exe1 SHARED ${LIB_SOURCES})
# Library-specific definitions
target_compile_definitions(lib_exe1 PRIVATE -DForExe1)
# The library specialized for exe2.
add_library(lib_exe2 SHARED ${LIB_SOURCES})
# Library-specific definitions
target_compile_definitions(lib_exe2 PRIVATE -DForExe2)

在需要时可以使用生成的库：

add_executable(exe1 ${SOUCE_FILES})
target_link_libraries(exe1 lib_exe1)

---

如果您的库应该针对某些编译定义进行参数化，请考虑创建一个 CMake 函数/宏，该函数/宏在需要时创建一个库实例：

function(add_lib_for lib_name purpose_name)
    add_library(${lib_name} SHARED <sources>)
    target_compile_definitions(${lib_name} PRIVATE
        -Dfoo -Dbar # Common definitions
        -DFor${purpose_name} # Specific definition
    )
endfunction()

用法：

add_executable(exe1 ${SOUCE_FILES})
add_lib_for(lib_exe1 Exe1)
target_link_libraries(exe1 lib_exe1)