Gradle Kotlin 构建脚本无法获取 SpringBoot Lib

Question

我在构建脚本上尝试了几种方法，但仍然没有成功将 springboot 库放入我的 jar，我可以知道我的脚本出了什么问题吗？

父 Gradle Kotlin DSL

import io.spring.gradle.dependencymanagement.dsl.DependencyManagementExtension
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
extra["kotlin.version"] = "1.3.31"
plugins {
    java
    idea
    id("org.springframework.boot") version "2.1.4.RELEASE" apply false
    kotlin("jvm") version "1.3.31" apply false
    kotlin("plugin.spring") version "1.3.31" apply false
}
subprojects {
    apply(plugin = "org.jetbrains.kotlin.jvm")
    apply(plugin = "org.jetbrains.kotlin.plugin.spring")
    apply(plugin = "io.spring.dependency-management")
    the<DependencyManagementExtension>().apply {
        imports {
            mavenBom(org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES)
        }
    }
    group = "com.company.market"
    version = System.getenv("VERSION") ?: "0.2-SNAPSHOT"
    java {
        sourceCompatibility = JavaVersion.VERSION_1_8
    }
    repositories {
        maven {
            credentials {
                username = "anonymous"
                password = "anonymous"
            }
            url = uri("http://repo1.maven.apache.org/maven2/")
        }
    }
    dependencies {
        implementation(kotlin("reflect"))
        implementation(kotlin("stdlib-jdk8"))
        testImplementation("org.springframework.boot:spring-boot-starter-test")
    }
    tasks.getByName<KotlinCompile>("compileKotlin") {
        kotlinOptions {
            freeCompilerArgs = listOf("-Xjsr305=strict")
            jvmTarget = "1.8"
        }
    }
    tasks.getByName<KotlinCompile>("compileTestKotlin") {
        kotlinOptions {
            freeCompilerArgs = listOf("-Xjsr305=strict")
            jvmTarget = "1.8"
        }
    }
}

Child (API( Gradle Kotlin DSL

下面是将用于部署的子模块

plugins {
    `java`
}
dependencies {
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.springframework.boot:spring-boot-starter-security")
    implementation("org.springframework.security.oauth:spring-security-oauth2:2.3.3.RELEASE")
    implementation("org.springframework.security.oauth.boot:spring-security-oauth2-autoconfigure:2.1.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-devtools")
    implementation("org.apache.commons:commons-dbcp2")
    implementation("org.mariadb.jdbc:mariadb-java-client")
    implementation("org.springframework.boot:spring-boot-loader:2.1.4.RELEASE")
    implementation(project(":app-expr"))
    implementation(project(":app-data"))
}

我可以成功构建 API 模块，但 jar 大小很小，并意识到库不是在 jar 内构建的。

Answer 1

我在我的子项目中添加了 springboot 库并解决了

plugins {
    `java`
    id("org.springframework.boot")
}
dependencies {
    implementation("org.springframework.boot:spring-boot-starter-web")
    implementation("org.springframework.boot:spring-boot-starter-security")
    implementation("org.springframework.security.oauth:spring-security-oauth2:2.3.3.RELEASE")
    implementation("org.springframework.security.oauth.boot:spring-security-oauth2-autoconfigure:2.1.4.RELEASE")
    implementation("org.springframework.boot:spring-boot-devtools")
    implementation("org.apache.commons:commons-dbcp2")
    implementation("org.mariadb.jdbc:mariadb-java-client")
    implementation("org.springframework.boot:spring-boot-loader:2.1.4.RELEASE")
    implementation(project(":expr"))
    implementation(project(":data"))
}