SPARQL代数:如果不存在任何三元组，则从命名图中进行棘手的ASK

Question

取这两个命名图：

# graph :yesterday
:Foo 
     :likes :Bar ;
     :likes :Qux .
# graph :today
:Foo
    :likes :Bar ;
    :likes :Baz .

现在假设你想知道图:yesterday中的三元组是否在图:today中不存在。您将如何ASK此查询？

ASK
FROM NAMED :yesterday
FROM NAMED :today
{
    GRAPH :yesterday {
        ?s ?p ?o .
        ...
    }
}

Answer 1

SPARQL有两个否定操作：使用您认为最自然的一个。当我阅读问题描述时，它读起来更像下面的第一个，但在这个问题的情况下，它们非常相似。当模式的一部分或另一部分与任何内容都不匹配或没有共同的变量时，它们的效果会有所不同。

NOT EXISTS测试是否存在模式（也存在EXISTS）。它是应用于第一个模式的每个解决方案的过滤器。它就像一个嵌套的ASK，其中变量也被替换为过滤器的传入变量。

PREFIX : <http://example/>
SELECT * {
  GRAPH :yesterday { ?s ?p ?o }
  FILTER NOT EXISTS { GRAPH :today { ?s ?p ?o } }
}

MINUS执行两个模式（左侧和右侧），然后返回左侧的行，其中右侧的任何位置都没有匹配的行。这是一种反加入。

PREFIX : <http://example/>
SELECT * {
  GRAPH :yesterday { ?s ?p ?o }
  MINUS { GRAPH :today { ?s ?p ?o } }
}

对于两者，我都得到：

------------------------
| s    | p      | o    |
========================
| :Foo | :likes | :Qux |
------------------------

TriG:

@prefix : <http://example/> .
:yesterday {
  :Foo 
     :likes :Bar ;
     :likes :Qux .
}
:today {
  :Foo
    :likes :Bar ;
    :likes :Baz .
}