使用 Proc sql 获取许多变量的统计信息

Question

我想使用 Porc sql 创建一个数据集，其中包含许多变量的最小和最大等一些统计信息。下面的代码只返回第一个变量的最小值和最大值数据集，其余变量 min 和 max 不显示在数据集中。

proc sql;
CREATE TABLE Lib.VarNum AS 
%do i=1 %to &nvars;
select  min(%SCAN(&numvar,&i)) as Min%SCAN(&numvar,&i),
max(%SCAN(&numvar,&i)) as Max%SCAN(&numvar,&i)
from &data (keep= _numeric_);
%end;
quit;

有人可以帮助我吗？

Answer 1

使用 proc 表示是执行此操作的最佳方法。

proc means data=sashelp.cars noprint;
var _numeric_;
output out=want (drop= _type_ _freq_ )min(_numeric_) =
max(_numeric_) =/autoname;
run;

但是如果你想通过Proc SQL最简单的宏变量从字典列并在你的表中使用它们。

/* creating macrovariables using dictionary.columns*/
proc sql noprint;
select 'min('|| trim(name)||') as min_'||name,
'max('|| trim(name)||') as max_'||name 
into :min separated by ',' , :max separated by ','
from dictionary.columns
where libname ='SASHELP'
and memname ='CARS'
and upcase(type) ='NUM';

可以检查宏变量的值，并且仅部分显示

%put &min;
min(MSRP) as min_MSRP,min(Invoice) as min_Invoice,min(EngineSize) as min_EngineSize

在 proc SQL 语句中使用此宏变量，如下所示。

proc sql;
create table want as 
select &min, &max from sashelp.cars;