如何记录任务列表的计数

Question

我有一个名为"Ulti.exe"的进程。由于我的项目要求，我在任何时候都有多个副本在运行。如果"Ulti.exe"的副本数量降至3以下，我需要终止所有进程并重新启动它们。

如何将TaskList计数保存到变量中？目前，以下命令：

TaskList | FIND /C "Ulti.exe"

如果键入cmd.exe，则会准确地返回"Ulti.exe"进程的数目。如何将其合并到.bat文件中，以便将此数字用作变量？

Answer 1

使用for /f循环获取命令的输出：

for /f %%a in ('TaskList ^| FIND /I /C "Ulti.exe"') do set count=%%a
echo %count%

Answer 2

计数时，如果需要，还可以收集PID以轻松杀死它们

:: Q:Test2018112SO_53115422.cmd
@Echo off & SetLocal EnableExtensions EnableDelayedExpansion
Set "Prog=Ulti.exe"
::Set "Prog=firefox.exe"
Set "Count="
Set "PIDs="
for /f "tokens=2" %%A in (
'TaskList /FI "IMAGENAME eq %Prog%" ^| Findstr /i "%Prog%"'
) do (
Set /A Count+=1
Set PIDs=!PIDs! /PID %%A
)
If defined Count (
If !Count! lss 3 (
echo taskkill %PIDs%
echo restart %Prog%
) else (
echo %Prog% running %Count% times [%PIDs%]
)
) else (
Echo %Prog% not running
Echo start %Prog%
)

样本输出：

> SO_53115422
Ulti.exe running 5 times [ /PID 3664 /PID 10332 /PID 3544 /PID 8996 /PID 11192]
> SO_53115422
Ulti.exe not running
start Ulti.exe
> SO_53115422
taskkill  /PID 8056 /PID 2704
restart Ulti.exe

taskkill命令仅在测试时得到响应