Emacs Lisp:如何使用交互式(条件参数)

Question

我想根据第一个问题的答案向用户提出第二个问题。

(defun something (a b)
  (interactive
   (list
    (read-number "First num: ")
    (read-number "Second num: ")))
  (message "a is %s and b is %s" a b))

所以我需要一种方法来测试条目值:

(defun something-else (a &optional b)
  (interactive
   (list
    (read-number "First num: ")
    (if (< a 2)
        (read-number "Second num: "))))
  (message "a is %s" a))

,

if: Symbol's value as variable is void: a

问题:我怎样才能以一种真正互动的方式使用interactive ?

Answer 1

(defun xtest (a &optional b)
  (interactive
   (let (a b)
     (setq a (read-number "First: "))
     (if (< a 2)
         (setq b (read-number "Second: ")))
     (list a b)))
  (message "a is %s b is %s" a b))

Answer 2

将interactive中的表单解释为一种子程序，该子程序将参数值列表作为返回值传递。在类似let的形式的帮助下，您可以在那里设置局部变量。

(defun something-else (a &optional b)
  (interactive
   (let* ((a-local (read-number "First num: "))
          (b-local (when (< a-local 2)
             (read-number "Second num: "))))
     (list a-local b-local)))
  (message "a is %s, b is %s" a b))

在上面的示例中，a-local和b-local是您选择的变量，它们的名称对于封闭的let* -形式是局部的。let*中的星号表示a-local的求值表达式(read-number "First num: ")在b-local的求值表达式(when (< a-local 2) (read-number "Second num: "))之前被赋值给a-local。