编辑后不刷新ALV.为什么?

Question

我知道我的问题已经被问了一百次了。但我仍然找不到任何适合我的解决方案

1. 我有一个下拉列表，每次我在下拉列表中更改数据时，它都会根据下拉数据加载新数据
2. 从第一步开始，我刷新可编辑ALV
3. 可编辑ALV中的任何更改都将被保存（另一个保存操作）

我的问题是，在我保存后，我无法刷新我的ALV。

但如果我没有按下保存按钮也没问题

注意：在SAP论坛上，他们告诉我将刷新功能转移到PBO，我尝试过，但还是失败了。

附加代码是步骤1是"；当SET_ P"；在这个代码

PBO

    MODULE pbo_1000 OUTPUT.
       IF flag = 0.
         SET PF-STATUS '1000'.
         SET TITLEBAR  '1000'.
         PERFORM create_toolbar.
         PERFORM create_catalog.
         PERFORM select_data.
     
         CREATE OBJECT ob_custom
           EXPORTING
             container_name = 'CCTRL'.
         CREATE OBJECT ob_grid
           EXPORTING
             i_parent      = ob_custom
             i_appl_events = 'X'.
     
         PERFORM create_dropbox.
         CALL METHOD ob_grid->set_table_for_first_display
           EXPORTING
             i_structure_name     = 'TYPE'
             it_toolbar_excluding = lt_toolbar
             is_layout            = lyt
           CHANGING
             it_fieldcatalog      = fld[]
             it_outtab            = itab[].
     
         CALL METHOD ob_grid->set_ready_for_input
           EXPORTING
             i_ready_for_input = 1.
         CALL METHOD ob_grid->register_edit_event
           EXPORTING
             i_event_id = cl_gui_alv_grid=>mc_evt_enter.
       ENDIF.
    ENDMODULE.   

PAI

    MODULE user_command_1000 INPUT .
       DATA: v_perio(6) TYPE c.
       CASE sy-ucomm.
         WHEN 'BACK' OR 'EXIT' OR 'CANCEL'.
           LEAVE TO SCREEN 0.
         WHEN 'SAVE'.
           PERFORM save_data.
           PERFORM send_email.
     
         WHEN 'SET_S'.
           flag = 1.
           PERFORM set_status.
           CALL METHOD ob_grid->refresh_table_display
             EXPORTING
               is_stable = stbl.
    
         WHEN 'SET_P'.
           flag = 1.
           PERFORM select_data.
           CALL METHOD ob_grid->refresh_table_display
             EXPORTING
               is_stable      = stbl.
       ENDCASE.
    ENDMODULE. 

Answer 1

我想您将需要作为PAI中的第一件事调用的CHECK_CHANGED_DATA方法，该方法将引发事件DATA_CHANGED和DATA_CHANGED_FINISHED

但最重要的是，它将使OLE对象与实例后端同步，然后当您调用REFRESH_ABLE_DISPLAY时，它将正确刷新ALV。我现在还没有任何例子，但我可以在下周访问系统时尝试一下。

顺便说一句，在PBO中，您不需要有变量标志，您可以使用检查ALV对象是否已经初始化，并根据这一点创建/刷新ALV。类似这样的东西：

if alvGridRef is NOT bound .
  data(container) = new cl_gui_custom_container( ) .
  data(alvGridRef) = new cl_gui_alv_grid( ) .
else .
  alvGridRef->refresh_table_display( ) .
endif .

Answer 2

我在一个应用程序中做过类似的事情，保存时需要刷新，因为一些计算必须在屏幕中更改。我在命令表单中为"REUSE_ALV_GRID_DISPLAY"功能模块设置了以下代码的一部分。

form user_command using r_ucomm     like sy-ucomm
                        rs_selfield type slis_selfield.
  data: ref_grid type ref to cl_gui_alv_grid, l_valid type c.
  if ref_grid is initial.
    call function 'GET_GLOBALS_FROM_SLVC_FULLSCR'
      importing
        e_grid = ref_grid.
  endif.
  if not ref_grid is initial.
    call method ref_grid->check_changed_data
      importing
        e_valid = l_valid.
  endif.
  rs_selfield-refresh = 'X'.
  ...
  if not ref_grid is initial.
    call method ref_grid->refresh_table_display( ) .
  endif.
endform.

希望它能帮助

Answer 3

您可以通过手动触发PBO来实现这一点。您声明编辑已保存，因此您可以再次在PBO中显示ALV：

CALL FUNCTION 'SAPGUI_SET_FUNCTIONCODE'
           EXPORTING
             functioncode           = 'REFRESH'
           EXCEPTIONS
             function_not_supported = 1 
             OTHERS                 = 2.

在该动作之后，PBO中的sy-ucomm具有值REFRESH。