我裁剪了一部分图像，并通过12个轨迹条定义了2个颜色范围(H/S/L)。我还有一个"精度/速度"滑块，范围从1到10。
我需要分析图像中每个指定颜色范围中有多少像素
基于精度/速度滑块，我跳过了一些行/像素。
它工作得很好，但太慢了。对于高精度(轨迹条值=1)，大约需要550毫秒。
对于低精度但高速度(轨迹条数值=10)，大约大约需要5毫秒。
有没有办法加快这个代码的速度？理想情况下，我需要它快5倍。
For y As Integer = 0 To 395
If y Mod 2 = 0 Then
startpixel = tbval / 2
Else
startpixel = 0
End If
If y Mod tbval = 0 Then
For x As Integer = 0 To 1370
If x Mod tbval - startpixel = 0 Then
analyzedpixels = analyzedpixels + 1
Dim pColor As Color = crop.GetPixel(x, y)
Dim h As Integer = pColor.GetHue
Dim s As Integer = pColor.GetSaturation * 100
Dim l As Integer = pColor.GetBrightness * 100
'verify if it is part of the first color
If h >= h1min And h <= h1max And s >= s1min And s <= s1max And l >= l1min And l <= l1max Then
color1pixels = color1pixels + 1
End If
If h >= h2min And h <= h2max And s >= s2min And s <= s2max And l >= l2min And l <= l2max Then
color2pixels = color2pixels + 1
End If
End If
Next
End If
Next
编辑：
这是工作代码。。
Dim rect As New Rectangle(0, 0, crop.Width, crop.Height)
Dim bdata As Imaging.BitmapData = crop.LockBits(rect, Imaging.ImageLockMode.ReadOnly, crop.PixelFormat)
Dim ptr As IntPtr = bdata.Scan0
Dim bytes As Integer = Math.Abs(bdata.Stride) * crop.Height
Dim rgbValues As Byte() = New Byte(bytes - 1) {}
System.Runtime.InteropServices.Marshal.Copy(ptr, rgbValues, 0, bytes)
For i As Integer = 0 To crop.Height - 1
If i Mod 2 = 0 Then
startpixel = tbval / 2
Else
startpixel = 0
End If
If i Mod tbval = 0 Then
For j As Integer = 0 To crop.Width - 1
If j Mod tbval - startpixel = 0 Then
analyzedpixels = analyzedpixels + 1
Dim position = (bdata.Stride * i) + j * 4
Dim c = Color.FromArgb(BitConverter.ToInt32(rgbValues, position))
Dim h As Integer = c.GetHue
Dim s As Integer = c.GetSaturation * 100
Dim l As Integer = c.GetBrightness * 100
If h >= h1min And h <= h1max And s >= s1min And s <= s1max And l >= l1min And l <= l1max Then
color1pixels = color1pixels + 1
End If
If h >= h2min And h <= h2max And s >= s2min And s <= s2max And l >= l2min And l <= l2max Then
color2pixels = color2pixels + 1
End If
End If
stride += 4
Next
End If
Next
crop.UnlockBits(bdata)
当对位图的颜色数据执行顺序操作时，Bitmap.LockBits方法可以大幅提高性能，因为位图数据只需要在内存中加载一次，而不是顺序的GetPixel/SetPixel调用：每次调用都会在内存中装载位图数据的一部分，然后丢弃它，以在再次调用这些方法时重复该过程。
如果只需要调用GetPixel/SetPixel，这些方法可能比Bitmap.LockBits()具有性能优势。但是，在这种情况下，在实践中，表现并不是一个因素。
Bitmap.LockBits()的工作原理：
这是函数调用：
public BitmapData LockBits (Rectangle rect, ImageLockMode flags, PixelFormat format);
// VB.Net
Public LockBits (rect As Rectangle, flags As ImageLockMode, format As PixelFormat) As BitmapData
rect As Rectangle：此参数指定我们感兴趣的位图数据的部分；此部分的字节将加载到内存中。它可以是位图的整个大小，也可以是位图中较小的部分flags AsImageLockMode：指定要执行的锁的类型。对内存的访问可以限制为读取或写入，或者允许并行读取/写入操作
它还可以用于指定-设置ImageLockMode.UserInputBuffer-BitmapData对象由调用代码提供BitmapData对象定义了一些位图属性(位图的Width和Height，扫描线的宽度(Stride：组成一行像素的字节数，由Bitmap.Width乘以每个像素的字节数来表示，四舍五入为4字节边界。请参阅有关Stride的说明)
BitmapData.Scan0属性是指向存储位图数据的初始内存位置的指针(IntPtr)
此属性允许指定已存储预先存在的位图数据缓冲区的内存位置。当使用指针在进程之间交换位图数据时，它会变得很有用
请注意，有关ImageLockMode.UserInputBuffer的MSDN文档令人困惑(如果没有错的话)。format AsPixelFormat：用于描述单个像素的颜色的格式。在实践中，它转换为用于表示颜色的字节数PixelFormat = Format24bppRgb时，每个颜色由3个字节(RGB值)表示。对于PixelFormat.Format32bppArgb，每个颜色由4个字节表示(RGB值+Alpha)
索引格式，如Format8bppIndexed，指定每个字节值都是Palette条目的索引。Palette是位图信息的一部分，但像素格式为PixelFormat.Indexed时除外：在这种情况下，每个值都是系统颜色表中的一个条目
如果未指定，则新位图对象的默认PixelFormat为PixelFormat.Format32bppArgb或PixelFormat.Canonical
关于Stride的重要注意事项：
如前所述，Stride(也称为扫描线)表示组成一行像素的字节数。由于硬件对齐要求，它总是四舍五入到4字节的边界(4的整数倍)。
Stride = [Bitmap Width] * [bytes per Color]
Stride += (Stride Mod 4) * [bytes per Color]
这就是为什么我们总是使用PixelFormat.Format32bppArgb创建的位图的原因之一：位图的Stride总是与所需的边界对齐。
如果位图的格式是PixelFormat.Format24bppRgb(每种颜色3个字节)，该怎么办？
如果位图的Width乘以每像素字节数不是4的倍数，则Stride将填充0以填补空白。
大小为(100 x 100)的位图在32位和24位格式中都没有填充：
100 * 3 = 300 : 300 Mod 4 = 0 : Stride = 300
100 * 4 = 400 : 400 Mod 4 = 0 : Stride = 400
大小为(99 x 100):的位图会有所不同
99 * 3 = 297 : 297 Mod 4 = 1 : Stride = 297 + ((297 Mod 4) * 3) = 300
99 * 4 = 396 : 396 Mod 4 = 0 : Stride = 396
24位位图的Stride被填充，添加3个字节(设置为0)以填充边界。
当我们检查/修改通过坐标访问单个像素的内部值时，这不是问题，类似于SetPixel/GetPixel的操作方式：像素的位置总是可以正确找到。
假设我们需要检查/更改大小为(99 x 100)的位图中位置(98, 70)处的像素
仅考虑每个像素的字节数。缓冲区内的像素位置为：
[Bitmap] = new Bitmap(99, 100, PixelFormat = Format24bppRgb)
[Bytes x pixel] = Image.GetPixelFormatSize([Bitmap].PixelFormat) / 8
[Pixel] = new Point(98, 70)
[Pixel Position] = ([Pixel].Y * [BitmapData.Stride]) + ([Pixel].X * [Bytes x pixel])
[Color] = Color.FromArgb([Pixel Position] + 2, [Pixel Position] + 1, [Pixel Position])
将像素的垂直位置乘以扫描线的宽度，缓冲区内的位置将始终正确：填充大小包含在计算中
下一个位置的像素颜色(0, 71)将返回预期结果：
按顺序读取颜色字节时会有所不同
第一个扫描行将返回有效结果，直到最后一个像素(最后3个字节)：接下来的3个字节将返回用于取整Stride的字节值，全部设置为0。
这可能也不是问题。例如，应用过滤器时，表示像素的每个字节序列都会使用过滤器矩阵的值进行读取和修改：我们只需修改3个字节的序列，在渲染位图时不会考虑这些字节。
但如果我们正在搜索特定的像素序列，这确实很重要：读取不存在的像素Color可能会影响结果和/或使算法失衡
对位图的颜色执行统计分析时也是如此。
当然，我们可以在循环中添加一个检查：if [Position] Mod [BitmapData].Width = 0 : continue
但这会为每次迭代添加一个新的计算。
实践中的操作
简单的解决方案(更常见的解决方案)是创建一个格式为PixelFormat.Format32bppArgb的新位图，因此Stride将始终正确对齐：
Imports System.Drawing
Imports System.Drawing.Imaging
Imports System.Runtime.InteropServices
Private Function CopyTo32BitArgb(image As Image) As Bitmap
Dim imageCopy As New Bitmap(image.Width, image.Height, PixelFormat.Format32bppArgb)
imageCopy.SetResolution(image.HorizontalResolution, image.VerticalResolution)
For Each propItem As PropertyItem In image.PropertyItems
imageCopy.SetPropertyItem(propItem)
Next
Using g As Graphics = Graphics.FromImage(imageCopy)
g.DrawImage(image,
New Rectangle(0, 0, imageCopy.Width, imageCopy.Height),
New Rectangle(0, 0, image.Width, image.Height),
GraphicsUnit.Pixel)
g.Flush()
End Using
Return imageCopy
End Function
这将生成具有相同DPI定义的字节兼容位图；图像。PropertyItems也从源映像中复制。
为了测试它，让我们对图像应用一个深褐色过滤器，使用它的副本来执行位图数据所需的所有修改：
Public Function BitmapFilterSepia(source As Image) As Bitmap
Dim imageCopy As Bitmap = CopyTo32BitArgb(source)
Dim imageData As BitmapData = imageCopy.LockBits(New Rectangle(0, 0, source.Width, source.Height),
ImageLockMode.ReadOnly, PixelFormat.Format32bppArgb)
Dim buffer As Byte() = New Byte(Math.Abs(imageData.Stride) * imageCopy.Height - 1) {}
Marshal.Copy(imageData.Scan0, buffer, 0, buffer.Length)
Dim bytesPerPixel = Image.GetPixelFormatSize(source.PixelFormat) 8;
Dim red As Single = 0, green As Single = 0, blue As Single = 0
Dim pos As Integer = 0
While pos < buffer.Length
Dim color As Color = Color.FromArgb(BitConverter.ToInt32(buffer, pos))
' Dim h = color.GetHue()
' Dim s = color.GetSaturation()
' Dim l = color.GetBrightness()
red = buffer(pos) * 0.189F + buffer(pos + 1) * 0.769F + buffer(pos + 2) * 0.393F
green = buffer(pos) * 0.168F + buffer(pos + 1) * 0.686F + buffer(pos + 2) * 0.349F
blue = buffer(pos) * 0.131F + buffer(pos + 1) * 0.534F + buffer(pos + 2) * 0.272F
buffer(pos + 2) = CType(Math.Min(Byte.MaxValue, red), Byte)
buffer(pos + 1) = CType(Math.Min(Byte.MaxValue, green), Byte)
buffer(pos) = CType(Math.Min(Byte.MaxValue, blue), Byte)
pos += bytesPerPixel
End While
Marshal.Copy(buffer, 0, imageData.Scan0, buffer.Length)
imageCopy.UnlockBits(imageData)
imageData = Nothing
Return imageCopy
End Function
Bitmap.LockBits不一定总是可用的最佳选择
使用ColorMatrix类也可以很容易地执行应用过滤器的相同过程，该类允许仅使用一个简单的浮点数组(Single)值将5x5矩阵转换应用于位图。
例如，让我们使用ColorMatrix类和众所周知的5x5矩阵应用灰度滤波器：
Public Function BitmapMatrixFilterGreyscale(source As Image) As Bitmap
' A copy of the original is not needed but maybe desirable anyway
' Dim imageCopy As Bitmap = CopyTo32BitArgb(source)
Dim filteredImage = New Bitmap(source.Width, source.Height, source.PixelFormat)
filteredImage.SetResolution(source.HorizontalResolution, source.VerticalResolution)
Dim grayscaleMatrix As New ColorMatrix(New Single()() {
New Single() {0.2126F, 0.2126F, 0.2126F, 0, 0},
New Single() {0.7152F, 0.7152F, 0.7152F, 0, 0},
New Single() {0.0722F, 0.0722F, 0.0722F, 0, 0},
New Single() {0, 0, 0, 1, 0},
New Single() {0, 0, 0, 0, 1}
})
Using g As Graphics = Graphics.FromImage(filteredImage), attributes = New ImageAttributes()
attributes.SetColorMatrix(grayscaleMatrix)
g.DrawImage(source, New Rectangle(0, 0, source.Width, source.Height),
0, 0, source.Width, source.Height, GraphicsUnit.Pixel, attributes)
End Using
Return filteredImage
End Function