如何使用 NeoJSON 在 Pharo 中解析 ndjson

Question

我想在Pharo Smalltalk上使用NeoJSON解析ndjson（换行符分隔的json）数据。

NDJSON 数据如下所示：

{"smalltalk": "cool"}
{"pharo": "cooler"}

目前，我将文件流转换为字符串，将其拆分为换行符，然后使用 NeoJSON 解析单个部分。这似乎使用了不必要（且极其巨大）的内存和时间，可能是因为一直将流转换为字符串，反之亦然。完成此任务的有效方法是什么？

如果您查找示例数据：NYPL-publicdomain：pd_items_1.ndjson

Answer 1

这是

Sven（NeoJSON的作者）在pharo-users邮件列表上的回答（他不在SO上）：

阅读"格式"很容易，只需继续为每个 JSON 表达式执行 #next（空格被忽略）。

| data reader |
data := '{"smalltalk": "cool"}
{"pharo": "cooler"}'.
reader := NeoJSONReader on: data readStream.
Array streamContents: [ :out |
  [ reader atEnd ] whileFalse: [ out nextPut: reader next ] ].

防止中间数据结构也很容易，使用流式处理。

| client reader data networkStream |
(client := ZnClient new)
  streaming: true;
  url: 'https://github.com/NYPL-publicdomain/data-and-utilities/blob/master/items/pd_items_1.ndjson?raw=true';
  get.
networkStream := ZnCharacterReadStream on: client contents.
reader := NeoJSONReader on: networkStream.
data := Array streamContents: [ :out |
  [ reader atEnd ] whileFalse: [ out nextPut: reader next ] ].
client close.
data.

花了几秒钟，毕竟网络上的50K项目是80MB +。

Answer 2

如果您打开一个新的 ReadWriteStream，首先将 ${ 写入它，然后将原始流的所有内容流式传输到上面，然后写入尾随的 $}，它会起作用吗？生成的流应该对 NeoJSON 有好处... ？这可能是对问题的 STTCPW 攻击，但 W 是不恰当的 ;-）而且它应该更快，更少的内存消耗，因为NeoJSON只会做一次传递。

只是一个想法，还没有尝试过。

Answer 3

你可以尝试这样的事情：

| input reader |
input := FileStream readOnlyFileNamed: 'resources/pd_items_1.ndjson.txt'.
[ 
Array
    streamContents: [ :strm | 
        | ln |
        [ (ln := input nextLine) isNil ] 
          whileFalse: [ strm nextPut: (NeoJSONReader fromString: ln) ] ] ] timeToRun.

除非这是你已经尝试过的...