通过反射获取getter具有可选值的属性的值

Question

我正在检索一个控件的几个属性。以下是我过去检索属性的方式（使用PropertyInfo类型的pinfo）：

value = pinfo.GetValue(obj, nothing)

这很好，但现在我遇到一个具有可选值的属性，并且我收到一条错误消息，告诉我参数的数量不正确。所以我更改了我的代码：

Dim index As Object() = {Nothing}
value = pinfo.GetValue(obj, index)

在这一点上，我没有收到任何错误消息，但这段代码没有检索到好的值。只有当我用属性访问器提供的默认值替换Nothing时，它才有效。。。

但是我事先不知道这个默认值是什么！这段代码位于函数中，该函数检索没有可选值的属性，因此我不能更改代码，尤其是在这种或那种情况下。。

知道吗？我正在开发.NET 2.0

<小时>

编辑：关于导致问题的案例的更精确信息

以下是导致问题的属性示例：

ReadOnly Property Foo(Optional ByVal Number As Integer = -1) As String
    Get
        If Number = -1 Then
            Return "Your number is the default number: " & Number
        Else
            Return "Your number is " & Number
        End If
    End Get
End Property

有了这种属性，上面的代码都不会检索到好的字符串。

我的最佳猜测是，出于一般目的，尝试第一段代码，捕获适当的异常，然后动态检索参数（在这种情况下为Number）的默认值及其类型，这样我就可以用这个默认值调用getValue。

那么，如何检索可选参数的默认值

Answer 1

这适用于可选参数：

ReadOnly Property Foo(Optional name As String = Nothing) As String
    Get
        If name Is Nothing Then
            Return "Hello World"
        Else
            Return "Hello " & name
        End If
    End Get
End Property

Dim pinfo As Reflection.PropertyInfo = Me.GetType().GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {"Tim"})  ' Hello Tim '
value = pinfo.GetValue(Me, New Object(){Nothing})               ' Hello World '

编辑：根据您的评论，整数不起作用，我还不知道如何在属性中获得可选参数的默认值。如果你知道它，你可以很容易地通过它，但否则会发生以下情况（注意Int32.MinValue是默认值，而不是0）：

ReadOnly Property Foo(Optional age As Int32 = Int32.MinValue) As String
    Get
        If age = Int32.MinValue Then
            Return "I don't know how old i am"
        Else
            Return String.Format("I am {0} years old", age)
        End If
    End Get
End Property
Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {38})  ' I am 38 years old '
value = pinfo.GetValue(Me, New Object() {Nothing})           ' I am 0 years old '
value = pinfo.GetValue(Me, New Object() {Int32.MinValue})    ' I don't know how old i am '

<小时>

Edit2：感谢@Rup，现在我知道GetIndexParameters是缺失的部分。所以以下内容应该适用于任何类型的参数。

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim parameters() As Reflection.ParameterInfo = pinfo.GetIndexParameters()
Dim params(parameters.Length - 1) As Object
For i As Int32 = 0 To parameters.Length - 1
    Dim paramInfo As Reflection.ParameterInfo = parameters(i)
    If paramInfo.IsOptional Then
        params(i) = paramInfo.DefaultValue
    Else
        If paramInfo.ParameterType.IsValueType Then
            params(i) = Activator.CreateInstance(paramInfo.ParameterType)
        Else
            params(i) = Nothing
        End If
    End If
Next
Dim value As Object = pinfo.GetValue(Me, params)

Answer 2

请尝试以下示例。验证对象是否为null，然后使用Activator将其激活。以下程序在C#中。

class Program
{
    static void Main(string[] args)
    {
        Test testObj = null;
        testObj = testObj ?? Activator.CreateInstance<Test>();
        var ty = testObj.GetType().GetProperty("MyProperty").GetValue(testObj, null);
    }
}
public class Test
{
    public Test2 MyProperty { get; set; }
}
public class Test2
{
    public int Prty { get; set; }
}