调用构造函数引发EInvalidCast

Question

我试图调用通过RTTI获得的构造函数(运行D2010版本14.0.3593.25826)。构造函数接受字符串和对象的混合参数，所有参数都应该初始化为''或nil。(免责声明:我知道期望的构造函数将具有最大数量的参数，因此看起来很奇怪，尽管不是最优的设计。)

代码如下:

program sb_rtti;
{$APPTYPE CONSOLE}
uses RTTI, TypInfo, SysUtils;
type
TMyClass = class (TObject)
  FField1:  string;
  FObject1: TObject;
public
  constructor Create(Field1: string = ''; Object1: TObject = nil);
end;
constructor TMyClass.Create(Field1: string; Object1: TObject);
begin
  FField1 := Field1;
  FObject1 := Object1;
end;
function GetConstructor(rType: TRttiType) : TRttiMethod;
var
  MaxParams:  integer;
  Methods:    TArray<TRttiMethod>;
  Method:     TRttiMethod;
  Params:     TArray<TRttiParameter>;
begin
  Methods := rType.GetMethods('Create');
  MaxParams := 0;
  for Method in Methods do begin
    Params := Method.GetParameters();
    if (Length(Params) > MaxParams) then begin
      Result := Method;
      MaxParams := Length(Params);
    end;
  end;
end;
procedure InitializeParam(Param: TRttiParameter; ActualParam: TValue);
begin
  if (Param.ParamType.TypeKind = TTypeKind.tkClass) then begin
    ActualParam := TValue.From<TObject>(nil);
  end else if (Param.ParamType.TypeKind = TTypeKind.tkString) then begin
    ActualParam := TValue.From<string>('');
  end else if (Param.ParamType.TypeKind = TTypeKind.tkUString) then begin
    ActualParam := TValue.From<UnicodeString>('');
  end else begin
    // Other types goes here
  end;
end;
var
  Context:      TRttiContext;
  Constr:       TRttiMethod;
  Params:       TArray<TRttiParameter>;
  ResultValue:  TValue;
  rType:        TRttiType;
  ActualParams: array of TValue;
  i:            integer;
  CurrentParam: TRttiParameter;
begin
  Context := TRttiContext.Create();
  rType := Context.GetType(TypeInfo(TMyClass));
  Constr := GetConstructor(rType);
  try
    if (Constr <> nil) then begin
      Params := Constr.GetParameters();
      SetLength(ActualParams, Length(Params));
      for i := 0 to Length(Params) - 1 do begin
        CurrentParam := Params[i] as TRttiParameter;
        InitializeParam(CurrentParam, ActualParams[i]);
      end;
      ResultValue := Constr.Invoke(rType.AsInstance.MetaclassType, ActualParams);
    end;
  except
    on E : Exception do
      WriteLn(E.ToString);
  end;
  ReadLn;
end.

现在，当ResultValue := Constr.Invoke(rType.AsInstance.MetaclassType, ActualParams);行被执行时，会引发一个EInvalidCast异常。该异常可以追溯到第1336行的TValue.Cast -方法。

然而，问题的核心似乎是在调用堆栈的前一点，更准确地说是在rtti中的第4093行。pas (argList[currArg] := Args[i].Cast(parList[i].ParamType.Handle);).

我敢打赌，我正在以我不应该的方式使用rtti，然而，我找不到任何地方描述的"正确方法"。谁能给我指个正确的方向?谢谢!

Answer 1

您在InitializeParam过程中遇到了问题，因为在分配ActualParam参数时，您正在设置该参数的本地副本的值-记住TValue (ActualParam的类型)是一个记录。因此，要解决这个问题，您必须将ActualParam作为var参数传递。

procedure InitializeParam(Param: TRttiParameter; var ActualParam: TValue);

Answer 2

我刚想到通过替换

来硬编码参数初始化

for i := 0 to Length(Params) - 1 do begin
  CurrentParam := Params[i] as TRttiParameter;
  InitializeParam(CurrentParam, ActualParams[i]);
end;

ActualParams[0] := TValue.From<string>('');
ActualParams[1] := TValue.From<TObject>(nil);

解决问题