像sql组一样对两个xml文件进行分组[2]

Question

这是我的问题的演变:像sql分组一样对两个xml文件进行分组给出的例子和Dimitre解计算不同的isbn值。现在将库xml修改为有mylibrary.xml:

<library>  
   <book id="1" isbn="1"/>
   <book id="2" isbn="1"/>
   <book id="3" isbn="2"/>
   <book id="4" isbn="4"/>
   <book id="5" isbn="5"/>
   <book id="6" isbn="4"/>
   <book id="7" isbn="4"/>   
</library>  

和这个可以使用:Bookreference.xml:

<reference>  
    <book isbn="1">  
        <category>SF</category>  
    </book>  
    <book isbn="2">  
        <category>SF</category>  
    </book>  
    <book isbn="3">  
        <category>SF</category>  
    </book>  
    <book isbn="4">  
        <category>Comedy</category>  
    </book>  
    <book isbn="5">  
        <category>Comedy</category>  
    </book>
</reference>  

我想获得我在mylibrary中得到的书的编号，即使有些有相同的isbn，按类别分组，使用XSLT 1-0。

输出:

SF : 3 book(s) 
Comedy : 4 book(s) 

我的xslt建议在这里:像sql group-by一样将两个xml文件分组工作得很好，但当然使用'for-each'循环和扩展函数。当然还有更好的解决办法。

Answer 1

又是一个非常好的问题!(+ 1)

这个转换，使用两个键来实现完全的效率:

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>
     <xsl:key name="kBookByCat" match="book"
          use="category"/>
     <xsl:key name="kBookByIsbn" match="book"
          use="@isbn"/>
     <xsl:variable name="vDoc" select="/"/>
     <xsl:variable name="vRef" select=
     "document('file:///c:/temp/delete/reference.xml')"/>
     <xsl:variable name="vMyIsbns" select="/*/*/@isbn"/>
     <xsl:variable name="vResult">
      <xsl:apply-templates select="$vRef/*"/>
     </xsl:variable>
     <xsl:template match="/">
      <xsl:copy-of select="$vResult"/>
     </xsl:template>
     <xsl:template match=
      "book[generate-id()
           =
            generate-id(key('kBookByCat', category)[1])
            ]
      ">
         <xsl:variable name="vBooksinCat" select=
              "key('kBookByCat', category)"/>
         <xsl:value-of select="category"/> : <xsl:text/>
         <xsl:for-each select="$vDoc">
           <xsl:value-of select="count(key('kBookByIsbn',$vBooksinCat/@isbn))"/>
         </xsl:for-each>
         <xsl:text> book(s)&#xA;</xsl:text>
     </xsl:template>
     <xsl:template match="text()"/>
</xsl:stylesheet>

应用于mylibrary.xml:

文件中提供的XML文档时

<library>
   <book id="1" isbn="1"/>
   <book id="2" isbn="1"/>
   <book id="3" isbn="2"/>
   <book id="4" isbn="4"/>
   <book id="5" isbn="5"/>
   <book id="6" isbn="4"/>
   <book id="7" isbn="4"/>
</library>

并在C:tempdeletereference.xml:

<reference>
    <book isbn="1">
        <category>SF</category>
    </book>
    <book isbn="2">
        <category>SF</category>
    </book>
    <book isbn="3">
        <category>SF</category>
    </book>
    <book isbn="4">
        <category>Comedy</category>
    </book>
    <book isbn="5">
        <category>Comedy</category>
    </book>
</reference>

产生所需的正确输出:

SF : 3 book(s)
Comedy : 4 book(s)

Answer 2

修改了Dimitri版本

<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:key name="kBookByCat" match="book" use="category"/>
<xsl:variable name="vRef" select="document('file:///c:/temp/delete/reference.xml')"/>
<xsl:variable name="meh" select="*"/>
<xsl:template match="/">
    <xsl:apply-templates select="$vRef/reference/book[generate-id()=generate-id(key('kBookByCat', category)[1])]" />
</xsl:template>
<xsl:template match="book">
    <xsl:variable name="cat" select="category"/>
    <xsl:value-of select="category"/> : <xsl:text/>
    <xsl:variable name="isbns" select="$vRef/reference/book[category=$cat]/@isbn"/>
    <xsl:value-of select="count($meh/book[@isbn=$isbns])"/>
    <xsl:text> book(s)&#xA;</xsl:text>
</xsl:template>

Answer 3

除了dimitri的回应之外，我建议在mylibrary中不打印0本书的图书类别:

<xsl:variable name="catname" select="category"/>
<xsl:for-each select="$vDoc">
    <xsl:variable name="cnt" select="count(key('kBookByIsbn',$vBooksinCat/@isbn))"/>
    <xsl:if test="$cnt &gt; 0">
        <xsl:value-of select="$catname"/> : 
        <xsl:text/>
        <xsl:value-of select="$cnt"/>
        <xsl:text> book(s)&#xA;</xsl:text>
    </xsl:if>
</xsl:for-each>