用于查找/替换文件中文本的批处理命令

Question

我有一个模板文件（比如myTemplate.txt），我需要进行一些编辑才能从这个模板创建我自己的文件（比如myFile.txt）。

所以模板包含类似的行

env.name=
env.prop= 
product.images.dir=/opt/web-content/product-images

现在，我希望将其替换如下；

env.name=abc
env.prop=xyz
product.images.dir=D:/opt/web-content/product-images

因此，我正在寻找批处理命令来执行以下操作；

1. Open the template file.
2. Do a kind of find/replace for the string/text
3. Save the updates as a new file

我该如何做到这一点？

Answer 1

最简单的方法是修改模板，使其看起来像这样：

env.name=!env.name!
env.prop=!env.prop!
product.images.dir=/opt/web-content/product-images

然后在启用延迟扩展时使用FOR循环读取和写入文件：

@echo off
setlocal enableDelayedExpansion
set "env.name=abc"
set "env.prop=xyz"
(
  for /f "usebackq delims=" %%A in ("template.txt") do echo %%A
) >"myFile.txt"

请注意，对整个循环使用一个重写重定向>要比在循环中使用附加重定向>>快得多。

以上假设模板中没有以;开头的行。如果他们这样做了，那么你需要将FOR EOL选项更改为一个永远不会开始一行的字符。也许相等-for /f "usebackq eol== delims="

此外，上面假设模板不包含任何需要保留的空行。如果有，那么您可以如下修改上述内容（这也消除了任何潜在的EOL问题）

@echo off
setlocal enableDelayedExpansion
set "env.name=abc"
set "env.prop=xyz"
(
  for /f "delims=" %%A in ('findstr /n "^" "template.txt"') do (
    set "ln=%%A"
    echo(!ln:*:=!
  )
) >"myFile.txt"

还有最后一个潜在的复杂性isse——如果模板包含!和^文字，则可能会出现问题。您可以对模板中的字符进行转义，也可以使用一些额外的替换。

template.txt

Exclamation must be escaped^!
Caret ^^ must be escaped if line also contains exclamation^^^!
Caret ^ should not be escaped if line does not contain exclamation point.
Caret !C! and exclamation !X! could also be preserved using additional substitution.

从templateProcessor.bat提取

setlocal enableDelayedExpansion
...
set "X=^!"
set "C=^"
...