流口水 JBOSS 规则 嵌套的 IF's

Question

我是Jboss规则的新手。我已经浏览了文档，但没有找到开始为以下代码示例编写规则的方法。

For each User code in the list 
{
    If User code = ‘11’ 
    {
        If User code ‘17’ present in the group 
        {
            Add letter id 1
        }
        Else If User code ‘18’ present in the group 
        {
            Add letter id 2
        }
    }
    Else 
    {
        Add letter id 3 which is the letter need to be sent for code 11
    }
}

编辑：

到目前为止，这是我可以为上面讨论的用户案例开发的。

1. 我正在将（UserDetailVo的列表）插入流口水会话
2. 对象（UserDetailVo）包含（UserInfoVo的列表）。每个UserInfoVo都包含一个代码

现在，我想迭代（List of UserInfoVo）并将（letterId）更新为每个（UserDetailVo），如下所述。

情况1：当codeList具有110121时

rule "USER LETTER GROUPING 110,121" 
salience 300
no-loop true
    when
        userDetailVo : UserDetailVo ()
        UserInfoVo(code=="110") from userDetailVo.codeList
        UserInfoVo(code=="121") from userDetailVo.codeList
    then
        userDetailVo.addLetterId(1);
        //modify(trrDetailRequestVo)
end
    

情况2：当codeList有110127时

rule "USER LETTER GROUPING 110,127" 
        salience 300
        no-loop true
    
            when
                userDetailVo : UserDetailVo ()
                UserInfoVo(code=="110") from userDetailVo.codeList
                UserInfoVo(code=="127") from userDetailVo.codeList
            then
                userDetailVo.addLetterId(2);
                //modify(trrDetailRequestVo)
        end

情况3：当codeList只有110时

rule "USER LETTER GROUPING 110" 
    salience 300
    no-loop true
    
        when
            userDetailVo : UserDetailVo (this.letterID.size() == 0) // Checking size of the list
            UserInfoVo(code=="110") from userDetailVo.codeList
        then
            userDetailVo.addLetterId(3);
            //modify(trrDetailRequestVo)
    end

我面临的问题是，如果我的用户在规则结束时修改/更新。它进入一个无限循环。如果我删除修改/更新，在情况3中，如果列表大小大于0，则仍会触发规则。

Answer 1

"else"的概念并不能直接转化为声明性语言。相反，您必须明确定义"else"在数据方面的真正含义，并根据该条件编写一条（或多条）规则。例如，考虑以下条件：

If Order Total >= 1000
  Discount = 15%
Else If Order Total >= 500
  Discount = 10%
Else If Order Total >= 250
  Discount = 5%
Else
  Discount = 0%

针对这些条件的规则的自然第一次尝试可能是：

rule "15% discount"
  when
    $o : Order( total >= 1000 )
  then
    modify($o) { setDiscount(.15); }
end
rule "10% discount"
  when
    $o : Order( total >= 500 )
  then
    modify($o) { setDiscount(.10); }
end
etc...

这种方法的问题是，10%和15%的规则都将与总数为1200的订单相匹配。这是因为"else-if"的"else"部分固有地包括订单总数不大于1000的条件。所以我们改为这样写规则：

rule "15% discount"
  when
    $o : Order( total >= 1000, discount == null )
  then
    modify($o) { setDiscount(.15); }
end
rule "10% discount"
  when
    $o : Order( total >= 500, total < 1000, discount == null )
  then
    modify($o) { setDiscount(.10); }
end
rule "5% discount"
  when
    $o : Order( total >= 250, total < 500, discount == null )
  then
    modify($o) { setDiscount(.05); }
end
rule "no discount"
  when
    $o : Order( total < 250, discount == null )
  then
    modify($o) { setDiscount(0); }
end

（您会注意到，我还添加了discount == null条件。这是为了防止在更新订单事实时重新激活规则。）

我一直在关注一个简单的例子，而不是您的特定用例，来演示编写条件以模仿"else"的概念。我仍然不确定我是否完全理解您的用例，但希望我已经回答了您问题的关键概念部分。

Answer 2

您可以实现如下嵌套的if：

rule "nested if else"
when 
o: Order(total >= 1000)
then
o.setDiscount("15%");
if(o.total>=500)
o.setDiscount("10%");
else if(o.total>=250)
o.setDiscount("5%");
else
o.setDiscount("0%");
end

您可以在then下编写任何java代码，例如循环、迭代、声明等。