LibGDX如何使用Sprites和SpriteBatch在单个位置组合两个纹理进行多重纹理处理

Question

使用LibGDX，我编写了一个非常简单的（也是我的第一个）片段着色器，它将设置两个不同的纹理，第一个是要绘制到屏幕上的图像，第二个是alpha透明度遮罩。这是片段着色器：

#ifdef GL_ES
    precision mediump float;
#endif
varying vec4 v_color;
varying vec2 v_texCoords;
uniform sampler2D u_texture;
uniform sampler2D u_mask;
void main() {
    vec4 texColor = texture2D(u_texture, v_texCoords);
    vec4 maskColor = texture2D(u_mask, v_texCoords);
    gl_FragColor = vec4(
        vec3(v_color * texColor),
        maskColor.a
    );
}

utexture是要绘制的图像，umask是具有透明度信息的纹理。

但是，我真正想做的是利用Sprite和TextureAtlas类来引用着色器的几个TextureRegion实例。这是我的渲染代码：

shaderBatch.setProjectionMatrix(camera.combined);
shaderBatch.begin();
// ... some housekeeping code ...
Sprite overlapAlphaMask = maskTextureAtlas.createSprite("mask", 4);
Sprite overlapSprite = spriteTextureAtlas.createSprite("some-tile", 8);
// Or some other index in the texture atlas
overlapAlphaMask.getTexture().bind(1);
alphaMaskShader.setUniformi("u_mask", 1);
overlapSprite.getTexture().bind(0);
alphaMaskShader.setUniformi("u_texture", 0);
shaderBatch.draw(overlapSprite, worldX, worldY, 1.0f, 1.0f);

尽管这至少是在运行和渲染一些东西，但它从maskTextureAtlas中拾取了错误的纹理区域。我的猜测是，这里还有更多的事情要做，因为着色器不会有任何关于overlapAlphaMask精灵的知识——如何绘制它，纹理坐标是什么，等等。

我假设SpriteBatch.draw()方法负责从传入的overlapSprite中获取正确的信息，所以我希望着色器中的vec2 v_texCoords已正确设置为绘制该信息，但这些坐标对于第二个纹理/sampler2D统一属性是错误的。这是我第一次尝试使用着色器，所以我确信我错过了一些基本的东西！

---更新---

到目前为止，我的谷歌搜索显示，我可能需要通过顶点着色器设置更多内容。我使用这个（默认？）libGDX顶点着色器：

attribute vec4 a_position;
attribute vec4 a_color;
attribute vec2 a_texCoord0;
uniform mat4 u_projTrans;
varying vec4 v_color;
varying vec2 v_texCoords;
void main() {
    v_color = a_color;
    v_texCoords = a_texCoord0;
    gl_Position = u_projTrans * a_position;
}

Answer 1

正如Dietrich Epp所指出的，我需要的是通过顶点缓冲区将额外的纹理坐标发送到顶点和像素着色器。我通过编写自己的SpriteBatch类实现实现了这一点，该类一次设置两个texture s（而不是TextureRegion s），并使用几个稍微扩展的着色器批量绘制这些着色器，如下所示：

顶点着色器

attribute vec4 a_position;
attribute vec4 a_color;
attribute vec2 a_texCoord0;
attribute vec2 a_texCoord1;
uniform mat4 u_projTrans;
varying vec4 v_color;
varying vec2 v_texCoords0;
varying vec2 v_texCoords1;
void main() {
    v_color = a_color;
    v_texCoords0 = a_texCoord0;
    v_texCoords1 = a_texCoord1;
    gl_Position = u_projTrans * a_position;
}

这是默认的顶点着色器，但将attribute vec2 a_texCoord替换为一组两个tex单词，并生成用于传递到片段着色器的varying vec2 v_texCoordsX。这个额外的CCD_ 13然后通过顶点缓冲器被发送进来。

片段着色器

#ifdef GL_ES
    precision mediump float;
#endif
varying vec4 v_color;
varying vec2 v_texCoords0;
varying vec2 v_texCoords1;
uniform sampler2D u_texture0;
uniform sampler2D u_texture1;
void main() {
    vec4 texColor = texture2D(u_texture0, v_texCoords0);
    vec4 maskColor = texture2D(u_texture1, v_texCoords1);
    gl_FragColor = vec4(
        vec3(v_color * texColor),
        maskColor.a
    );
}

类似地，片段着色器现在接收两个要从中采样的sampler2D纹理，以及每个纹理要参考的一对纹理坐标。

SpriteBatch类更改的关键是扩展构造函数中的Mesh定义：

    mesh = new Mesh(Mesh.VertexDataType.VertexArray, false, size * 4, size * 6, new VertexAttribute(VertexAttributes.Usage.Position, 2,
            ShaderProgram.POSITION_ATTRIBUTE), new VertexAttribute(VertexAttributes.Usage.ColorPacked, 4, ShaderProgram.COLOR_ATTRIBUTE),
            new VertexAttribute(VertexAttributes.Usage.TextureCoordinates, 2, ShaderProgram.TEXCOORD_ATTRIBUTE + "0"),
            new VertexAttribute(VertexAttributes.Usage.TextureCoordinates, 2, ShaderProgram.TEXCOORD_ATTRIBUTE + "1"));

上面的最后一行是新添加的a_texCoord1的一对坐标。向draw()方法传递两个Sprite或TextureRegion实例，并对其进行轻微扩展，以将每个点/索引的每组顶点的2个额外浮点传递给顶点阵列。最后，对着色器进行了轻微的添加，以绑定两个纹理并将统一设置为：

    shader.setUniformi("u_texture0", 0);
    shader.setUniformi("u_texture1", 1);

它起作用了！我的临时解决方案是将两个精灵绘制到屏幕上，并将透明度信息写入显示缓冲区，但由于每个纹理的SpriteBatch批处理，以及我的图像被分割到多个纹理，这导致了不可接受的性能损失，该解决方案已修复了这一问题：）