在 SAS 中使用 Proc SQL 时出现'Invalid column name'错误 (WPS)

Question

我正在测试一个非常小的宏，它使用 Proc SQL 命令从 SQL 数据库中提取。我已经使用过很多次并了解它是如何工作的，但这次它难倒了我！

%macro Correlation(dsn,db,prevdb,prodcode,sqltable,var,brick);
proc sql;
    connect to ODBC (required="DSN=&dsn;" );
    create table comp_correlation as select * from connection to ODBC
    (select a.Table_Name,
            a.Variable,
            a.Correlation as Current_Corr
        from DBTest.dbo.MetaData as a
        where Product_Code=&prodcode. and Table_Name=&sqltable. and 
     variable=&var.);
     disconnect from ODBC;
quit;
%mend;

然后，我使用以下参数调用此宏。我的服务器名称被审查，但我可以向您保证它连接成功。

%Correlation(********, A2019, A2018, HouseValues, Houses, Value);

但是，它返回以下错误：

[Microsoft][SQL Server Native Client 11.0][SQL Server]Invalid column name 'HouseValues'.

有人知道为什么会这样吗？我什至没有尝试选择产品代码作为列，它只在我的 where 语句中？

Answer 1

您

似乎错过了以下调用中的一个参数：

%相关性(********，A2019，A2018，房屋价值，房屋，价值(;

是错别字还是我解释错了？

谢谢

Answer 2

我现在已经使用 %bquote 宏修复了这个问题。

%macro Correlation(dsn,db,prevdb,prodcode,sqltable,var,brick);
proc sql;
    connect to ODBC (required="DSN=&dsn;" );
    create table comp_correlation as select * from connection to ODBC
    (select a.Table_Name,
        a.Variable,
        a.Correlation as Current_Corr
      from DBTest.dbo.MetaData as a
     where Product_Code=%bquote('&prodcode') and Table_Name=%bquote('&sqltable') and 
 variable=%bquote('&var'));
 disconnect from ODBC;
quit;
%mend;

Answer 3

听起来您的实际错误是您将字符串值传递给远程数据库而不带引号。您可以通过在宏调用中传递引号来解决这个问题。

%macro Correlation(dsn,db,prevdb,prodcode,sqltable,var,brick);
proc sql;
    connect to ODBC (required="DSN=&dsn;" );
    create table comp_correlation as select * from connection to ODBC
    (select a.Table_Name,
            a.Variable,
            a.Correlation as Current_Corr
        from DBTest.dbo.MetaData as a
        where Product_Code=&prodcode. and Table_Name=&sqltable. and 
     variable=&var.);
     disconnect from ODBC;
quit;
%mend;
%Correlation(dsn=********,db=A2019,prevdb=A2018
   ,prodcode='HouseValues', sqltable='Houses', var='Value');

请注意，您可以在宏调用中使用参数名称，即使对于定义为允许按位置调用参数的参数也是如此。

您还可以使您的宏更智能一点，并让它添加引号。 您甚至可以使其足够智能，以删除值周围的任何可选的现有双引号并用单引号替换它们。

%let prodcode=%sysfunc(quote(%qsysfunc(dequote(%superq(prodcode)))),%str(%'));

然后你可以随心所欲地调用它。

prodcode=HouseValues
prodcode="HouseValues"
prodcode='HouseValues'