我在Visual Studio 2010中使用XSL。我有以下*XSL*文件,我正试图使用tokenize()
函数来拆分字符串:
<xsl:stylesheet version='2.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform' >
<xsl:output media-type="text/html; charset=UTF-8" encoding="UTF-8"/>
<xsl:template match='/'>
<html>
<head> </head>
<body>
<ul>
<xsl:apply-templates select="response/result/doc"/>
</ul>
</body>
</html>
</xsl:template>
<xsl:template match="doc">
<xsl:variable name="title" select="str[@name='Title']"/>
<xsl:variable name="features" select="tokenize(str[@name='Desc'],';')"/>
<li>
<xsl:value-of select="$title"/>
<ul>
<xsl:for-each select="$features">
<li>
<xsl:value-of select="."/>
</li>
</xsl:for-each>
</ul>
</li>
</xsl:template>
</xsl:stylesheet>
注意:在这一点上,我不确定我是否真的在使用XSLT 2.0版本。我想我这样做是因为我在第一行设置了它
对于上述XSL,我在Visual Studio 2010中得到以下错误:
'tokenize()' is an unknown XSLT function.
我有以下输入XML文件:
<?xml version="1.0" encoding="UTF-8"?>
<response>
<result name="response" numFound="10000" start="0">
<doc>
<str name="Title">Title 1</str>
<str name="Desc">Feature 1; Feature 2; Feature 3;</str>
</doc>
<doc>
<str name="Title">Title 2</str>
<str name="Desc">Feature 1; Feature 2; Feature 3;</str>
</doc>
</result>
</response>
理想情况下,我希望有一个类似于HTML文件的输出:
<html>
<head> </head>
<body>
<ul>
<li>Title 1
<ul>
<li>Feature 1</li>
<li>Feature 2</li>
<li>Feature 3</li>
</ul>
</li>
<li>Title 2
<ul>
<li>Feature 1</li>
<li>Feature 2</li>
<li>Feature 3</li>
</ul>
</li>
</ul>
</body>
</html>
如何tokenize()
或拆分XML文件中的字符串Desc?请忽略其中的空白,即输出文件前后的一点额外空间没有意义,因为输出是HTML。
XSLT 2.0。当您尝试执行XSLT 2.0样式表时,在尝试使用2.0函数时会出现错误。
选项1:以下XSLT1.0样式表使用递归模板在不使用tokenize()
函数的情况下实现相同的结果:
<xsl:stylesheet version='1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform' >
<xsl:output media-type="text/html; charset=UTF-8" encoding="UTF-8"/>
<xsl:template match='/'>
<html>
<head> </head>
<body>
<ul>
<xsl:apply-templates select="response/result/doc"/>
</ul>
</body>
</html>
</xsl:template>
<xsl:template match="doc">
<li>
<xsl:value-of select="str[@name='Title']"/>
<ul>
<xsl:call-template name="listItem">
<xsl:with-param name="features" select="str[@name='Desc']"/>
</xsl:call-template>
</ul>
</li>
</xsl:template>
<xsl:template name="listItem">
<xsl:param name="features"/>
<xsl:param name="delimiter" select="';'"/>
<xsl:choose>
<xsl:when test="contains($features, $delimiter)">
<li>
<xsl:value-of select="normalize-space(
substring-before($features, $delimiter))"/>
</li>
<xsl:variable name="nextValue" select="substring-after($features,
$delimiter)"/>
<xsl:if test="normalize-space($nextValue)">
<xsl:call-template name="listItem">
<xsl:with-param name="features" select="$nextValue"/>
<xsl:with-param name="delimiter" select="$delimiter"/>
</xsl:call-template>
</xsl:if>
</xsl:when>
<xsl:otherwise>
<li>
<xsl:value-of select="$features"/>
</li>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
选项2:您还应该能够在Visual Studio中添加EXSLT.NET引用,然后能够使用EXSLT str:tokenze()函数:
<xsl:stylesheet version='1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
xmlns:str="http://exslt.org/strings" >
<xsl:output media-type="text/html; charset=UTF-8" encoding="UTF-8"/>
<xsl:template match='/'>
<html>
<head> </head>
<body>
<ul>
<xsl:apply-templates select="response/result/doc"/>
</ul>
</body>
</html>
</xsl:template>
<xsl:template match="doc">
<li>
<xsl:value-of select="str[@name='Title']"/>
<ul>
<xsl:for-each select="str:tokenize(str[@name='Desc'], ';')">
<li>
<xsl:value-of select="normalize-space(.)"/>
</li>
</xsl:for-each>
</ul>
</li>
</xsl:template>
</xsl:stylesheet>
您在第一行中指示样式表需要XSLT2.0环境,但错误消息指示您使用的是XSLT1.0环境。