Oracle - 如何区分空字符串和非空字符串

Question

在一个匿名块中，我有一个空/空的输入字符串，并希望根据非空字符串进行检查。例：

DECLARE 
v_notnull varchar2(50):='this string is never null';
v_input varchar2(50):='';
BEGIN
    IF trim(v_input) != trim(v_notnull) THEN
        dbms_output.put_line('the strings do NOT match');
    ELSE 
        dbms_output.put_line('the strings DO match');
    END IF; 
END;

这里的问题是，当我运行此块时，即使我将空字符串''(又名 null(输入到与字符串'this string is never null'不同的v_input中，输出也总是'the strings DO match'。 如何确保预言机涵盖空字符串大小写？当v_input为空时，我希望输出'the strings do NOT match'。

Answer 1

该文档有一节是关于空处理的。空字符串被视为与 null 相同，并且您不能将 null(任何类型的(与相等进行比较 - 如文档中的表格所示，将任何内容与 null 进行比较的结果是未知的 - 既不真也不假。您必须使用 is [not] null 来比较任何与 null 的内容。

在这种情况下，你可以明确地拼写出来，通过查看一个变量是 null 而另一个不是，反之亦然，并且只有在告诉您两者都不是 null 时才比较实际值：

DECLARE 
v_notnull varchar2(30):='this string is never null';
v_input varchar2(30):='';
BEGIN
    IF (trim(v_input) is null and trim(v_notnull) is not null)
      or (trim(v_input) is not null and trim(v_notnull) is null)
      or trim(v_input) != trim(v_notnull) THEN
        dbms_output.put_line('the strings do NOT match');
    ELSE 
        dbms_output.put_line('the strings DO match');
    END IF;
END;
/
the strings do NOT match

PL/SQL procedure successfully completed.

我添加了缺少的varchar2大小;大概您基于一个过程，该过程在没有单独运行您发布的内容的情况下进行参数......

Answer 2

''在

oracle中NULL。因此，任何与 null 的比较都将始终导致 false。

演示：

SQL> DECLARE
  2  v_notnull varchar2(1000):='this string is never null';
  3  v_input varchar2(1000):='';
  4  BEGIN
  5      IF v_input is null THEN
  6          dbms_output.put_line('v_input is null');   -- should print because v_input is actually null
  7      END IF;
  8
  9      IF trim(v_input) = trim(v_notnull) THEN        -- always false because of null
 10          dbms_output.put_line('the strings do NOT match');
 11      ELSE
 12          dbms_output.put_line('the strings DO match');  -- so should print this
 13      END IF;
 14  END;
 15  /
v_input is null            -- verified
the strings DO match       -- verified
PL/SQL procedure successfully completed.
SQL>

Answer 3

通常，您只关心值是否匹配，在这种情况下，null值没有区别：

declare
    v_notnull varchar2(50) := 'this string is never null';
    v_input   varchar2(50) := '';
begin
    if trim(v_input) = trim(v_notnull) then
        dbms_output.put_line('the strings DO match');
    else
        dbms_output.put_line('the strings do NOT match');
    end if;
end;

在某些情况下，您可以使用 coalesce() 或 nvl() 表达式简化可为 null 值的比较：

if nvl(v_yesno,'N') <> 'Y' then ...

您可能可以使用虚拟比较值(当然，根据具体情况，它存在与实际值匹配的风险(：

if nvl(somevalue, chr(0)) <> nvl(othervalue, chr(0)) then ...

顺便说一下，您可以通过将值复制到char变量来区分null和''，因为''将触发其通常无用的空白填充行为。我真的想不出这种情况会很有用，而只是为了好玩：

declare 
    v1 varchar2(1) := null;
    v2 varchar2(1) := '';
    c char(1);
begin
    c := v1;
    if v1 is null and c is not null then
        dbms_output.put_line('v1 = ''''');
    elsif c is null then
        dbms_output.put_line('v1 is null');
    end if;
    c := v2;
    if v2 is null and c is not null then
        dbms_output.put_line('v2 = ''''');
    elsif c is null then
        dbms_output.put_line('v2 is null');
    end if;
end;

输出：

v1 is null
v2 = ''