可以测试Job DSL脚本吗

Question

理想情况下，在Jenkins上执行脚本之前，我希望能够通过某种单元测试来调用脚本。

除了让jenkins运行JobDSL脚本之外，还有什么方法可以测试它吗？

Answer 1

除了作业dsl-gradle示例中的示例之外，您还可以更进一步，为单个文件或作业编写测试。例如，假设您有一个位于jobs/deployJob.groovy 中的作业配置文件

import javaposse.jobdsl.dsl.DslScriptLoader
import javaposse.jobdsl.dsl.MemoryJobManagement
import javaposse.jobdsl.dsl.ScriptRequest
import spock.lang.Specification
class TestDeployJobs extends Specification {
    def 'test basic job configuration'() {
        given:
        URL scriptURL = new File('jobs').toURI().toURL()
        ScriptRequest scriptRequest = new ScriptRequest('deployJob.groovy', null, scriptURL)
        MemoryJobManagement jobManagement = new MemoryJobManagement()
        when:
        DslScriptLoader.runDslEngine(scriptRequest, jobManagement)
        then:
        jobManagement.savedConfigs.each { String name, String xml ->
            with(new XmlParser().parse(new StringReader(xml))) {
                // Make sure jobs only run manually
                triggers.'hudson.triggers.TimerTrigger'.spec.text().isEmpty()
                // only deploy every environment once at a time
                concurrentBuild.text().equals('false')
                // do a workspace cleanup
                buildWrappers.'hudson.plugins.ws__cleanup.PreBuildCleanup'
                // make sure masked passwords are active
                !buildWrappers.'com.michelin.cio.hudson.plugins.maskpasswords.MaskPasswordsBuildWrapper'.isEmpty()
            }
        }
    }
}

通过这种方式，您可以遍历每个需要确保设置了所有正确值的XML节点。

Answer 2

看看job dsl-gradle的例子。repo包含DSL脚本的测试。

Answer 3

以与crasp相同的方式进行，但使用Jenkins单元测试页面中解释的Jenkins测试工具，速度较慢，但可以使用自动生成的DSL，如这里解释的那样，会出现语法错误。

按照这里解释的设置代码后，您可以进行这样的测试：

@Unroll
void 'check descriptions #file.name'(File file) {
    given:
    JobManagement jobManagement = new JenkinsJobManagement(System.out, [:], new File('.'))
    Jenkins jenkins = jenkinsRule.jenkins
    when:
    GeneratedItems items = new DslScriptLoader(jobManagement).runScript(file.text)
    then:
    if (!items.jobs.isEmpty()) {
        items.jobs.each { GeneratedJob generatedJob ->
            String text = getItemXml(generatedJob, jenkins)
            with(new XmlParser().parse(new StringReader(text))) {
                // Has some description
                !description.text().isEmpty()
            }
        }
    }
    where:
    file << TestUtil.getJobFiles()
}