DWScript: Getting from IScriptObj to IInfo or TProgramInfo

Question

给定一个IScriptObj参考，如何获得相应的IInfo或TProgramInfo？

---

我有一个包装德尔菲对象的脚本对象。

为了管理脚本对象的生存期，Delphi 对象存储对脚本对象的引用。脚本对象是使用 TdwsUnit 组件声明的。这是非常标准的，如下所示：

德 尔 福

type
  TDelphiObject = class
  private
    FScriptObject: IScriptObj;
  public
    procedure DoSomething;
    property ScriptObject: IScriptObj read FScriptObject write FScriptObject;
  end;

脚本

type
  TScriptObject = class
  protected
    procedure DoSomething; virtual;
  public
    constructor Create;
  end;

Delphi

对象的实例化和 Delphi/脚本链接的设置发生在脚本对象构造函数的 Delphi 实现中。也非常标准：

德 尔 福

// Implements TScriptObject.Create
procedure TMyForm.dwsUnitClassesTScriptObjectConstructorsCreateEval(Info: TProgramInfo; var ExtObject: TObject);
var
  DelphiObject: TDelphiObject;
  DelphiObjectInfo: IInfo;
begin
  // Create the Delphi-side object
  DelphiObject := TDelphiObject.Create;
  // Get the script object "self" value
  DelphiObjectInfo := Info.Vars['self'];
  // Store the ScriptObject reference
  DelphiObject.ScriptObject := DelphiObjectInfo.ScriptObj;
  // Return the instance reference to the script
  ExtObject := DelphiObject;
end;

理想情况下，我会保存IInfo引用，而不是IScriptObj，因为IInfo稍后会完成我需要的一切，但根据经验，IInfo对象似乎仅在方法调用期间有效。

无论如何，当在德尔福端调用TDelphiObject.DoSomething时，问题稍后会出现。 TDelphiObject.DoSomething用于在脚本对象上调用相应的虚拟方法：

德 尔 福

procedure TDelphiObject.DoSomething;
var
  Info: IInfo;
  DoSomethingInfo: IInfo;
begin
  // I have a IScriptObj but I need a IInfo...
  Info := { what happens here? };
  // Call the virtual DoSomething method
  DoSomethingInfo := Info.Method['DoSomething'];
  DoSomethingInfo.Call([]);
end;

---

我尝试了很多不同的技术来从存储的IScriptObj中获取可用的IInfo或TProgramInfo，但每件事都失败了。那么正确的方法是什么呢？

Answer 1

问题原来是我假设我需要一个IInfo接口来封装对象实例，但显然 DWScript 不是这样工作的。我需要的是创建一个指向实例的临时引用/指针，然后在该实例上创建一个IInfo。

这是

如何完成的：

procedure TDelphiObject.DoSomething;
var
  ProgramExecution: TdwsProgramExecution;
  ProgramInfo: TProgramInfo;
  Data: TData;
  DataContext: IDataContext;
  Info: IInfo;
  DoSomethingInfo: IInfo;
begin
  (*
  ** Create an IInfo that lets me access the object represented by the IScriptObj pointer.
  *)
  // FProgramExecution is the IdwsProgramExecution reference that is returned by
  // TdwsMainProgram.CreateNewExecution and BeginNewExecution. I have stored this
  // elsewhere.
  ProgramExecution := TdwsProgramExecution(FProgramExecution);
  ProgramInfo := ProgramExecution.AcquireProgramInfo(nil);
  try
    // Create a temporary reference object
    SetLength(Data, 1);
    Data[0] := FScriptObject;
    ProgramInfo.Execution.DataContext_Create(Data, 0, DataContext);
    // Wrap the reference
    Info := TInfoClassObj.Create(ProgramInfo, FScriptObject.ClassSym, DataContext);

    // Call the virtual DoSomething method
    DoSomethingInfo := Info.Method['DoSomething'];
    DoSomethingInfo.Call([]);
  finally
    ProgramExecution.ReleaseProgramInfo(ProgramInfo);
  end;
end;

这样做是启用从 Delphi 到脚本的面向对象的回调。没有这个，只能从 Delphi 调用全局脚本函数。

FWIW，上面有以下两行：

ProgramInfo.Execution.DataContext_Create(Data, 0, DataContext);
Info := TInfoClassObj.Create(ProgramInfo, FScriptObject.ClassSym, DataContext);

可以替换为对CreateInfoOnSymbol的调用(在 dwsinfo 中声明(：

CreateInfoOnSymbol(Info, ProgramInfo, FScriptObject.ClassSym, Data, 0);