名称.使用变量在 VBA 中添加

Question

如何使用以下变量创建以下不连续的命名范围？

    ActiveWorkbook.Names.Add Name:="Validation_Range", RefersToR1C1:= _
    "='Holding Template'!R3C1,'Holding Template'!R4C2"

以下是变量：

Dim PM As Range
Dim statement_date As Range
Set PM = ws.Range("A3")
Set statement_date = ws.Range("B4")

如果我使用 1 个变量它可以工作，但我无法使用多个变量来创建不连续的范围。

Answer 1

目前尚不清楚如何获取两个范围以设置变量，但这里有一些使用 Union 方法的速记选项。

Dim pm As Range, statement_date As Range
With Worksheets("Holding Template")
    Union(.Cells(3, 1), .Cells(4, 2)).Name = "Validation_Range"
    'alternate
    'Union(.Range("A3"), .Range("B4")).Name = "Validation_Range"
    'alternate
    'Set pm = .Range("A3")
    'Set statement_date = .Range("B4")
    'Union(pm, statement_date).Name = "Validation_Range"
End With

这些方法中的任何一种都会创建工作簿范围的命名区域，或覆盖具有工作簿范围的现有Validation_Range命名区域的 RefersTo： 。

Answer 2

手动创建一个您想要的名称，然后查看它是如何组合在一起的。然后编写代码来组装这样的字符串。

这样的事情似乎有效：

Sub test()
    Dim PM As Range, ws As Worksheet
    Dim statement_date As Range
    Set ws = Sheets("Holding Template")
    Set PM = ws.Range("A3")
    Set statement_date = ws.Range("B4")
    ActiveWorkbook.Names.Add Name:="Validation_Range", RefersTo:= _
        "='" & ws.Name & "'!" & PM.Address & ",'" & ws.Name & "'!" & statement_date.Address
End Sub

Answer 3

以下是我重命名电子表格中所有标题的方法：

Sub renameheader()
i = 5
For x = 1 To 30
Worksheets("CHECKALL_LIST").Cells(1, i).Name = "Checks_" & x
i = i + 3
Next
End Sub

标题每 3 个单元格合并一次，这就是我需要使用"i"的原因。 希望这有帮助。