关于重复属性的说明

Question

我在示例xslt上有这段代码，但我无法准确地制作这一部分。我想了解这部分seq_no[/*/*/seq_no[@num = following::seq_no/@num]]。知道吗？

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="seq_no[/*/*/seq_no[@num = following::seq_no/@num]]">
        <seq_no num="[{count(preceding::seq_no)+1}]{.}">
            <xsl:apply-templates/>
        </seq_no>
    </xsl:template>
</xsl:stylesheet>

这是输入

<xml>
    <staff>
        <seq_no num="0">0</seq_no>
        <name>xyz</name>
    </staff>
    <staff>
        <seq_no num="1">1</seq_no>
        <name>xyz</name>
    </staff>
    <staff>
        <seq_no num="1">2</seq_no>
        <name>abc</name>
    </staff>
    <staff>
        <seq_no num="3">3</seq_no>
        <name>abc</name>
    </staff>
</xml>

这是输出

<xml>
   <staff>
      <seq_no num="[1]0">0</seq_no>
      <name>xyz</name>
   </staff>
   <staff>
      <seq_no num="[2]1">1</seq_no>
      <name>xyz</name>
   </staff>
   <staff>
      <seq_no num="[3]2">2</seq_no>
      <name>abc</name>
   </staff>
   <staff>
      <seq_no num="[4]3">3</seq_no>
      <name>abc</name>
   </staff>
</xml>

Answer 1

您正在尝试理解表达式seq_no[/*/*/seq_no[@num = following::seq_no/@num]]。它有助于将其分解为单独的部分。考虑以下内容：

/*/*/seq_no

因为此表达式以/开头，所以这是一个绝对路径，并且将匹配文档中作为XML根元素的子元素的任何seq_no元素。您可以使用以下xpath表达式对其进行量化：

[@num = following::seq_no/@num]

因此，它正在寻找一个seq_no元素，该元素的num属性与文档中该元素后面的另一个seq_no

但事实上，它在这里是一条绝对路径，这意味着它与您匹配的seq_no无关。因此，如果文档中的任何位置确实存在重复项，则表达式[/*/*/seq_no[@num = following::seq_no/@num]将返回true，因此您的模板将与文档中的ALLseq_no元素匹配。

请注意，这不是很有效，因为您正在为文档中的每个seq_no元素计算表达式，即使所有元素的值始终相同。最好先将其作为变量求值一次，然后在模板匹配中使用xsl:choose来确定是否需要更新属性值。

试试这个XSLT，例如

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output omit-xml-declaration="yes" indent="yes"/>
   <xsl:strip-space elements="*"/>
   <xsl:variable name="duplicate" select="/*/*/seq_no[@num = following::seq_no/@num]"/>
   <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node()|@*"/>
      </xsl:copy>
   </xsl:template>
   <xsl:template match="seq_no/@num">
      <xsl:choose>
         <xsl:when test="$duplicate">
            <xsl:attribute name="num">
               <xsl:number count="seq_no" level="any"/>
               <xsl:value-of select="concat('[', ., ']')"/>
            </xsl:attribute>
         </xsl:when>
         <xsl:otherwise>
            <xsl:copy/>
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>
</xsl:stylesheet>

注意，我已经更改了模板以匹配此处的num属性，因为这是您实际转换的XML的唯一部分。此外，我还使用xsl:number进行计数。