播放flv使用netStream appendBytes

Question

我知道有很多方法可以播放FLV文件，但考虑到我的项目要求，我需要使用URLStream和NetStream播放FLV

下面是我正在进行测试的完整示例代码:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.NetStatusEvent;
    import flash.events.ProgressEvent;
    import flash.utils.ByteArray;
    import flash.net.URLRequest;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.NetStreamAppendBytesAction;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    import flash.net.URLStream;
    /**
     * ...
     * @author Hadi Tavakoli
     */
    public class Main extends Sprite 
    {
        private var netConnection:NetConnection;
        private var netStream:NetStream;
        private var ul:URLStream;
        private var video:Video;
        private var bytes:ByteArray = new ByteArray();
        private var _isSeek:Boolean = false;
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point
            video = new Video();
            addChild(video);
            netConnection = new NetConnection();
            netConnection.addEventListener(NetStatusEvent.NET_STATUS, netConnectionStatusHandler);
            netConnection.connect(null);
        }
        private function netConnectionStatusHandler(ev:NetStatusEvent):void
        {
            switch(ev.info.code)
            {
                case 'NetConnection.Connect.Success':
                    ul = new URLStream();
                    ul.addEventListener(ProgressEvent.PROGRESS, onProgress);
                    ul.load(new URLRequest('01.flv'));
                break;
            }
        }
        private function onProgress(e:ProgressEvent):void
        {
            ul.readBytes(bytes, bytes.length);
            if (!netStream) 
            {
                netStream = new NetStream(netConnection);
                netStream.client = { };
                video.attachNetStream(netStream);
                netStream.play(null);
                trace("BEGIN")
                netStream.appendBytesAction(NetStreamAppendBytesAction.RESET_BEGIN);
            }
            else
            {
                if (!_isSeek)
                {
                    trace("SEEK")
                netStream.appendBytesAction(NetStreamAppendBytesAction.RESET_SEEK);
                    _isSeek = true;
                }
            }
            if (bytes.length == e.bytesTotal)
            {
                trace("END")
            netStream.appendBytesAction(NetStreamAppendBytesAction.END_SEQUENCE);
            }
            netStream.appendBytes(bytes);
            trace("-")
        }
    }
}

我不确定我是否正确使用"appendBytes"方法?视频显示，但只有极少数的第一帧将播放，然后视频停止!

在我眼里一切都好!你对我的问题在哪里有什么建议吗?

Answer 1

我认为你不需要if (!_isSeek)块。当你按顺序接收字节时，看起来你是在推入字节，所以从来没有寻道。看起来它将推入第一组字节，然后附加一个seek操作，并附加其余的字节。试着删除那个块，看看它是否有效。

Answer 2

in "readBytes(bytes, bytes.length);"行，我猜有一个错误。这对我来说也从来不起作用。它总是返回完整长度(从0到可用字节)。所以它有一个巨大的内存泄漏。但是如果你使用的是flash player 11.4或更高版本，你可以这样修改。

ul.position = bytes.length;
ul.readBytes(bytes);