Haxe宏，从生成的var setter调用静态方法

Question

我正在使用haxe宏向变量添加getter和setter，现在我正试图从新生成的setter中调用一个静态函数：

public static function build():Array<Field> {
//.........
// create setter
var setterBody = macro {
    $variableRef = v;
    // mypackage.MyClass.myFunc(this) <-------- DOES NOT WORK!!
    return $variableRef;
};
newFields.push({
    pos: Context.currentPos(),
    name: "set_" + field.name,
    meta: [],
    kind: FieldType.FFun({
            ret: readType,
            params: [],
            expr: setterBody,
            args: [{
                value: null,
                type: readType,
                opt: false,
                name: "v"
            }]
        }),
    doc: "",
    access: []
});

在上面的代码中，我找不到调用MyClass.myFun(this)的方法，我不知道如何为setter生成该代码，this指的是调用setter的对象的实例。

非常感谢。

Answer 1

如果没有一个更完整的例子，很难知道出了什么问题。我能做的是向你展示有效的代码：

TiagoLrMacroTest.hx:

@:build( TiagoLrMacro.build() )
class TiagoLrMacroTest {
    public static function main() {
        var test = new TiagoLrMacroTest();
        test.name = "hello";
    }
    function new() {}
    public var name(default,set):String;
}
class MyStaticClass {
        public static function staticMethod( a:TiagoLrMacroTest ) {
        trace( a.name );
    }
}

TiagoLrMacro.hx

import haxe.macro.Expr;
import haxe.macro.Context;
class TiagoLrMacro {
    public static function build():Array<Field> {
        var fields = Context.getBuildFields();
        var setterBody = macro {
            name = v;
            TiagoLrMacroTest.MyStaticClass.staticMethod( this );
            return name;
        };
        fields.push({
            pos: Context.currentPos(),
            name: "set_name",
            meta: [],
            kind: FieldType.FFun({
                ret: macro :String,
                params: [],
                expr: setterBody,
                args: [{
                    value: null,
                    type: macro :String,
                    opt: false,
                    name: "v"
                }]
            }),
            doc: "",
            access: []
        });
        return fields;
    }
}

结果（Haxe 3.1.3）：

TiagoLrMacroTest.hx:15: hello

在宏中调用静态方法时，我遇到的一个常见问题是不尊重导入，因此必须使用像mypackage.MyClass.myFunc(this)这样的全类型路径，但您已经在这样做了，所以错误一定在代码中的其他地方。快乐宏ing：）