非 sysdba 可以编译dbms_session吗?

Question

我正在尝试在我的一个存储过程中使用 sys.dbms_session.set_context，但出现以下错误：

ORA-01031: insufficient privileges

我的问题是我不能在我的存储过程中使用它，但是......当我以具有执行权限(和 sysdba 权限(的用户身份连接执行它时，我收到相同的错误(权限不足(。 这是代码：

PROCEDURE set_my_env (p_attribute IN VARCHAR2,p_value IN VARCHAR2)
IS
l_namespace   VARCHAR2 (30) := 'MY_ENV';
l_attribute   VARCHAR2 (30) := NULL;
l_value       VARCHAR2 (4000) := NULL;
BEGIN
l_attribute := p_attribute;
l_value := p_value;
DBMS_OUTPUT.PUT_LINE('NAMESPACE: ' || l_namespace);
DBMS_OUTPUT.PUT_LINE('Attribute: ' || l_attribute);
DBMS_OUTPUT.PUT_LINE('value: ' || l_value);
DBMS_SESSION.set_context (l_namespace, l_attribute, l_value);
END set_my_env;

当我以非 sysdba 用户(但它具有执行权限(执行此代码时，我收到权限不足错误。

提前谢谢。

Answer 1

DBMS_SESSION

是一个内置包，它与数据库安装一起安装，有效且随时可用。为什么要编译它(尤其是作为普通用户连接(？

无论如何，回到你的问题：为什么其他用户不能编译它？因为它属于别人。.SYS。授予execute特权意味着您可以使用它，而不是编译它。

为了能够编译其他人的过程(包，等等(，您需要被授予alter any procedure系统权限。但是，这不包括 SIS 拥有的对象。为了重新编译这些，您必须连接as sysdba。

---

如果你想让它(dbms_session(工作，方法如下：以SYS连接，向用户授予所需的权限(在我的示例中scott(：

SQL> show user
USER is "SYS"
SQL> grant create any context, drop any context, alter session, unlimited tablespace to scott;
Grant succeeded.
SQL> grant execute on dbms_session to scott;
Grant succeeded.
SQL>

现在，按scott连接;这仍然不起作用：

SQL> connect scott/tiger
Connected.
SQL> exec dbms_session.set_context('my_context', 'my_parameter', 'Littlefoot');
BEGIN dbms_session.set_context('my_context', 'my_parameter', 'Littlefoot'); END;
*
ERROR at line 1:
ORA-01031: insufficient privileges
ORA-06512: at "SYS.DBMS_SESSION", line 101
ORA-06512: at line 1

您要做的是创建一个将用于上下文业务的包，并创建使用该包的上下文。这是一个简化版本，你会使用更聪明的东西：

SQL> create or replace package pkg_context as
2    procedure p_set;
3  end;
4  /
Package created.
SQL> create or replace package body pkg_context as
2    procedure p_set as
3      begin
4        dbms_session.set_context('my_context', 'my_parameter', 'Littlefoot');
5      end;
6  end;
7  /
Package body created.
SQL> create context my_context using pkg_context;
Context created.
SQL>

现在我们准备好了！

SQL> exec pkg_context.p_set;
PL/SQL procedure successfully completed.
SQL> select sys_context('my_context', 'my_parameter') from dual;
SYS_CONTEXT('MY_CONTEXT','MY_PARAMETER')
--------------------------------------------------------------------------------
Littlefoot
SQL>

对;现在它按预期工作。