调整字段以存储到数据库

Question

说我有一个json的字段content。我想将其存储在数据库中，以便我的域类仅保留1个字段。(这更多是大脑任务;-)

class MyDomain{
   def content
   static constraints = {
        content nullable: false, blank: false, sqlType: "text" // adapter from JSON to String??
    }
def beforeInsert(){
    content = content.toString()
}
def beforeUpdate(){
    content = content.toString()
}
def afterInsert(){
    content = JSON.parse(content) as JSON
}
def afterUpdate(){
    content = JSON.parse(content) as JSON
}
def onLoad(){
    content = JSON.parse(content) as JSON
}
}

我希望我的域对象仅暴露content，因此我不想使用其他字段，例如String contentAsText，因为它在外面可见。

在整个Gorm文档中，我没有找到如何管理它的东西。我尝试了beforeValidate()/beforeInsert()和onLoad()方法，但没有运气...

在值持续之前如何调整该值？

Answer 1

您可以为JSONElement定义自定义Hibernate user-type，如下所述：https：//stackoverflow.com/a/a/28655708/607038

在域类约束中：

static constraints = {
   content type: JSONObjectUserType
}

用户类型类：

import org.grails.web.json.JSONObject
import org.hibernate.HibernateException
import org.hibernate.engine.spi.SessionImplementor
import org.hibernate.type.StandardBasicTypes
import org.hibernate.usertype.EnhancedUserType
import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types
class JSONObjectUserType implements EnhancedUserType, Serializable {
    private static final int[] SQL_TYPES = [Types.VARCHAR]
    @Override
    public int[] sqlTypes() {
        return SQL_TYPES
    }
    @Override
    public Class returnedClass() {
        return JSONObject.class
    }
    @Override
    public boolean equals(Object x, Object y) throws HibernateException {
        if (x == y) {
            return true
        }
        if (x == null || y == null) {
            return false
        }
        JSONObject zx = (JSONObject) x
        JSONObject zy = (JSONObject) y
        return zx.equals(zy)
    }
    @Override
    public int hashCode(Object object) throws HibernateException {
        return object.hashCode()
    }
    @Override
    public Object nullSafeGet(ResultSet resultSet, String[] names, SessionImplementor session, Object owner)
        throws HibernateException, SQLException {
        Object jsonObject = StandardBasicTypes.STRING.nullSafeGet(resultSet, names, session, owner)
        if (jsonObject == null) {
            return null
        }
        return new JSONObject((String) jsonObject)
    }
    @Override
    public void nullSafeSet(PreparedStatement preparedStatement, Object value, int index, SessionImplementor session)
        throws HibernateException, SQLException {
        if (value == null) {
            StandardBasicTypes.STRING.nullSafeSet(preparedStatement, null, index, session)
        } else {
            JSONObject jsonObject = (JSONObject) value
            StandardBasicTypes.STRING.nullSafeSet(preparedStatement, jsonObject.toString(), index, session)
        }
    }
    @Override
    public Object deepCopy(Object value) throws HibernateException {
        return value
    }
    @Override
    public boolean isMutable() {
        return false
    }
    @Override
    public Serializable disassemble(Object value) throws HibernateException {
        return (Serializable) value
    }
    @Override
    public Object assemble(Serializable cached, Object value) throws HibernateException {
        return cached
    }
    @Override
    public Object replace(Object original, Object target, Object owner) throws HibernateException {
        return original
    }
    @Override
    public String objectToSQLString(Object object) {
        throw new UnsupportedOperationException()
    }
    @Override
    public String toXMLString(Object object) {
        return object.toString()
    }
    @Override
    public Object fromXMLString(String string) {
        return new JSONObject(string)
    }
}

Answer 2

class MyDomain{
   JSONElement content
   static constraints = {
        content nullable: false, blank: false, sqlType: "text" // adapter from Map to String??
    }
    def setContent(String textContent){
        content = JSON.parse(textContent)
    }
}

我必须做2件事。

1. 用JSON content替换def content，以使其持久，请参见Grails域构造函数不是Groovy构造函数
2. 通过def setContent()将JSON字符串转换回JSON。

作为content是JSONElement使用JSONObject和JSONArray作为具体类。