如果只有 1 个孩子，则需要删除 xmi 节点

Question

如果只有 1 个孩子，我需要删除 XMI 节点。如果我删除 xmi 节点，我需要将属性复制到新的根节点。

<xmi:XMI attribute="2" xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A">
<namespace:node attribute2="att">
...
</namespace:node>
</xmi:XMI>

我需要得到

<namespace:node attribute2="att" attribute="2" xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A">
...
</namespace:node>

但如果有

<xmi:XMI attribute="2" xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A">
<namespace:node attribute2="att">
...
</namespace:node>
<otherNode/>
</xmi:XMI>

无需进行任何更改。

任何帮助表示赞赏。

Answer 1

此 XSLT 1.0 转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xmi="http://www.omg.org/spec/XMI/20110701">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>
 <xsl:template match="xmi:XMI[not(*[2])]">
  <xsl:apply-templates/>
 </xsl:template>
 <xsl:template match="xmi:XMI[not(*[2])]/*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@* | ../@*"/>
     </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

应用于以下 XML 文档时：

<xmi:XMI attribute="2"
           xmlns:xmi="http://www.omg.org/spec/XMI/20110701"
           xmlns:a="A" >
        <namespace:node attribute2="att" xmlns:namespace="some:namespace">
          ...
        </namespace:node>
        <otherNode/>
</xmi:XMI>

产生所需的正确结果（无更改）：

<xmi:XMI xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A" attribute="2">
   <namespace:node xmlns:namespace="some:namespace" attribute2="att">
          ...
        </namespace:node>
   <otherNode/>
</xmi:XMI>

应用于此 XML 文档时：

<xmi:XMI attribute="2"
           xmlns:xmi="http://www.omg.org/spec/XMI/20110701"
           xmlns:a="A" >
        <namespace:node attribute2="att" xmlns:namespace="some:namespace">
          ...
        </namespace:node>
</xmi:XMI>

再次生成所需的正确结果（xmi:XMI元素被"删除"，其属性被复制到其唯一的子元素）：

<namespace:node xmlns:namespace="some:namespace"    
 xmlns:xmi="http://www.omg.org/spec/XMI/20110701" xmlns:a="A" 
 attribute="2" attribute2="att">
          ...
</namespace:node>

Answer 2

尝试

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xmi="http://www.omg.org/spec/XMI/20110701">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* , node()"/>
  </xsl:copy>
</xsl:template>
<xsl:template match="xmi:XMI[not(*[2])">
  <xsl:apply-templates/>
</xsl:template>
<xsl:template match="xmi:XMI[not(*[2])]/*">
  <xsl:copy>
    <xsl:apply-templates select="../@*, @*, node()"/>
  </xsl:copy>
</xsl:template>
</xsl:stylesheet>