Perl超时输出消息

Question

我正在编程一个perl脚本，以监视使用nagios的数据库。我正在使用time的时间:: hires库进行超时。

use Time::HiRes qw[ time alarm ];
alarm $timeout;

一切正常。问题是我想更改输出消息，因为它会返回" elemizador"，如果我做

echo $?

返回142.我想更改消息以制作"退出3"，以便可以由Nagios识别。

已经尝试过" eval"但行不通。

Answer 1

花费时间写在C中，这使您无法安全使用自定义信号处理程序。

您似乎不担心有力终止您的程序，因此我建议您在没有信号处理程序的情况下使用alarm，如果运行时间太长，可以用信号处理程序终止您的程序，并使用包装器对Nagios提供正确的响应。

更改

/path/to/program some args

to

/path/to/timeout_wrapper 30 /path/to/program some args

以下是timeout_wrapper：

#!/usr/bin/perl
use strict;
use warnings;
use POSIX       qw( WNOHANG );
use Time::HiRes qw( sleep time );
sub wait_for_child_to_complete {
   my ($pid, $timeout) = @_;
   my $wait_until = time + $timeout;
   while (time < $wait_until) {
      waitpid($pid, WNOHANG)
         and return $?;
      sleep(0.5);
   }
   return undef;
}
{
   my $timeout = shift(@ARGV);
   defined( my $pid = fork() )
      or exit(3);
   if (!$pid) {
      alarm($timeout);   # Optional. The parent will handle this anyway.
      exec(@ARGV)
         or exit(3);
   }
   my $timed_out = 0;
   my $rv = wait_for_child_to_complete($pid, $timeout);
   if (!defined($rv)) {
      $timed_out = 1;
      if (kill(ALRM => $pid)) {
         $rv = wait_for_child_to_complete($pid, 5);
         if (!defined($rv)) {
            kill(KILL => $pid)
         }
      }
   }
   exit(2) if $timed_out;
   exit(3) if $rv & 0x7F;  # Killed by some signal.
   exit($rv >> 8);         # Expect the exit code to comply with the spec.
}

使用Nagios插件返回代码。超时应实际返回2。

Answer 2

您应该处理ALRM信号。例如：

#!/usr/bin/env perl
use strict;
use warnings;
use Time::HiRes qw[ time alarm ];
$SIG{ALRM} = sub {print "Custom messagen"; exit 3};
alarm 2;
sleep 10; # this line represents the rest of your program, don't include it

这将输出：

18:08:20-eballes@urth:~/$ ./test.pl 
Custom message
18:08:23-eballes@urth:~/$ echo $?
3

有关处理信号的扩展说明