无法将模板应用于子元素

我有一个XML文件，其中包含嵌套在<p>元素中的另一个元素中的子元素。我的XSLT很好地提取了<p>元素，但忽略了<span>。我知道这与xPath有关，但是我不知道如何使用这个XSLT结构来实现它。

<newsItem>
<inlineXml>
<h2>Calendar</h2> 
 <p><strong><span class="dates">June 16-18:</span>National Conference, Denver</strong></p>
 <p><strong><span class="dates">June 19-21:</span>Local Event, Chicago</strong></p>
<inlineXml>
</newsItem>

这是我的XSLT:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
 <xsl:output method="xml" indent="no"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="newsItem">
 <newsItem><xsl:apply-templates/></newsItem>
 </xsl:template>
 <xsl:template match="h2">
 <h2><xsl:value-of select="normalize-space(.)"/></h2>
 </xsl:template>
 <xsl:template match="p/strong/span">
 <date><xsl:value-of select="."/></date>
 </xsl:template> 
 <xsl:template match="p">
 <p><xsl:value-of select="normalize-space(.)"/></p>
 </xsl:template>
 </xsl:stylesheet>

下面是期望的结果:

<newsItem>
<inlineXml>
<h2>Calendar</h2> 
 <p><date>June 16-18:</date>National Conference, Denver</p>
 <p><date>June 19-21:</date>Local Event, Chicago</p>
<inlineXml>
</newsItem>

这可能很简单，但它难倒了我。

谢谢

如果您更改:

<xsl:template match="p">
   <p><xsl:value-of select="normalize-space(.)"/></p>
</xsl:template>

<xsl:template match="p">
  <p><xsl:apply-templates/></p>
</xsl:template>

你的结果将变成:

<?xml version="1.0"?>
<newsItem>
  <h2>Calendar</h2>
  <p><date>June 16-18:</date>National Conference, Denver</p>
  <p><date>June 19-21:</date>Local Event, Chicago</p>
</newsItem>

非常接近预期结果，只是缺少<inlineXml>包装器。这是因为没有匹配它的模板，所以如果你添加:

<xsl:template match="inlineXml">
   <inlineXml><xsl:apply-templates/></inlineXml>
</xsl:template>

你会得到预期的结果。

注意现在你有三个非常相似的模板:

<xsl:template match="newsItem">
   <newsItem><xsl:apply-templates/></newsItem>
</xsl:template>
<xsl:template match="p">
   <p><xsl:apply-templates/></p>
</xsl:template>
<xsl:template match="inlineXml">
   <inlineXml><xsl:apply-templates/></inlineXml>
</xsl:template>

可以组合成一个

<xsl:template match="newsItem | inlineXml | p">
    <xsl:copy>
        <xsl:apply-templates/>
    </xsl:copy>
</xsl:template>

参见:https://en.wikipedia.org/wiki/Identity_transform

这个XSLT 1.0样式表…

<xsl:stylesheet
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
 <xsl:output method="html" version="5" encoding="utf-8" indent="yes"/>
 <xsl:strip-space elements="*"/>
 <xsl:template match="/">
   <html>
     <head>
       <title>Inline XML</title>
     </head>
     <body>
       <xsl:apply-templates />
     </body>
   </html>
 </xsl:template>
<xsl:template match="@*|node()">
  <xsl:copy>
    <xsl:apply-templates />
  </xsl:copy>
</xsl:template>
<xsl:template match="strong[span/@class='dates']">
  <xsl:apply-templates />
</xsl:template>
<xsl:template match="strong/span[@class='dates']">
  <date>
    <xsl:apply-templates />
  </date>
</xsl:template>
</xsl:stylesheet>

…将转换这个输入文档…

<newsItem>
  <inlineXml>
    <h2>Calendar</h2> 
    <p><strong><span class="dates">June 16-18:</span>National Conference, Denver</strong></p>
    <p><strong><span class="dates">June 19-21:</span>Local Event, Chicago</strong></p>
  </inlineXml>
</newsItem>

…进入这个输出的HTML页面…

<!DOCTYPE HTML>
<html>
   <head>
      <meta http-equiv="Content-Type" content="text/html; charset=utf-8">
      <title>Inline XML</title>
   </head>
   <body>
      <newsItem>
         <inlineXml>
            <h2>Calendar</h2>
            <p>
               <date>June 16-18:</date>National Conference, Denver
            </p>
            <p>
               <date>June 19-21:</date>Local Event, Chicago
            </p>
         </inlineXml>
      </newsItem>
   </body>
</html>

一些建议
没有理由被限制到XSLT 1.0，您可以升级到XSLT 2.0，即使是在浏览器平台上(由Saxon提供)CE)。
如果你的`date`元素是一个微格式，你应该考虑html 5元素`time`。

相关内容

最新更新

热门标签：

无法将模板应用于子元素

一些建议没有理由被限制到XSLT 1.0，您可以升级到XSLT 2.0，即使是在浏览器平台上(由Saxon提供)CE)。如果你的date元素是一个微格式，你应该考虑html 5元素time。

相关内容

最新更新

热门标签：

一些建议
没有理由被限制到XSLT 1.0，您可以升级到XSLT 2.0，即使是在浏览器平台上(由Saxon提供)CE)。
如果你的`date`元素是一个微格式，你应该考虑html 5元素`time`。