ML :匹配非详尽

Question

我想使名为headcol的函数工作如下：

headcol[[1,2],[3,4]] = [1,3]; 

所以我做了这样的函数：

fun headcol [] = [] 
| headcol [x::xs',y::ys'] = [x,y]

但是当我打电话时，我得到了一个不详尽的匹配。

Answer 1

IIUC，headcol将提取参数中所有列表的头部，其类型为'a-list-list。你的数学只是[]和[x::xs', y::ys']，没有别的。因此，如果您的参数有 2 个以上的子列表，则 execption 将引发：

- headcol[[1,2],[3,4], [4, 5, 9]]; 
uncaught exception Match [nonexhaustive match failure]
raised at: a.sml:9.34
- 

如果你只想处理双磁列表，对是更好的选择。否则，您应该匹配更多案例：

fun headcol list =
case list of
[] => []
| x::xs' =>
case x of
[] => headcol xs'
|  h::t => h::(headcol xs')

输出：

- headcol[[1,2],[3,4], [4, 5, 9]]; 
- val it = [1,3,4] : int list

Answer 2

正如陳力所指出的，很难回答仅由函数名称及其尝试的解决方案定义的问题。不过，head听起来你想获取每个子列表的第一个元素，col听起来你把这个列表列表视为一个矩阵，其中列与子列表正交。

递归解决方案也可能如下所示：

fun headcol [] = []
| headcol ((x::_)::xss) = x :: headcol xss
| headcol ([]::xss) = headcol xss

以下是使用内置的高阶列表组合器的方法：

fun headcol xss =
List.concat (List.map (fn xs => List.take (xs, 1)) xss)

我不是简单地做的原因：

fun headcol xss =
List.map hd xss

是因为hd是部分函数，所以hd []会在运行时崩溃。

另一方面，List.take ([], 1)将返回[].

List.concat会将临时结果[[1],[2],[3]]合并到[1,2,3]中。

或者，如果缺少列，请[[1],[],[3]][1,3].

测试用例：

val test_headcol_0 = headcol [] = []
val test_headcol_1 = headcol [[1]] = [1]
val test_headcol_2 = headcol [[1,2],[3,4]] = [1,3]
val test_headcol_3 = headcol [[1,2,3],[4,5,6],[7,8,9]] = [1,4,7]
val test_headcol_4 = headcol [[1],[2,3],[4,5,6]] = [1,2,4]
val test_headcol_5 = headcol [[1],[],[2,3]] = [1,2]

当然，我不知道这是否是您对没有头列的不规则矩阵headcol所期望的行为。这是一个你不深入的极端情况。在函数式编程中，您经常将错误处理嵌入到返回值中，而不是引发异常。

例如，您可能希望从headcol返回一个'a list option，其中SOME [1,4,7]建议每一行都有一个 head 列，而NONE建议至少有一行未能生成列。

或者，您可以使用'a list list以外的数据类型来表示不允许缺少列的行的矩阵，例如 Array2。