F# 隐式键入在简单递归时阻塞

Question

>当我在 F# 中定义递归函数时：

let rec recursiveSum inputs =
    let startState = 0.0m
    if List.length inputs = 1 then
        startState + inputs.Head
    else
        let t = List.tail inputs
        startState + inputs.Head + recursiveSum t

。一切都很好。当我试图避免"空列表"问题时：

let rec recursiveSum inputs =
    let startState = 0.0m
    **if List.isEmpty inputs then startState**
    if List.length inputs = 1 then
        startState + inputs.Head
    else
        let t = List.tail inputs
        startState + inputs.Head + recursiveSum t

。我被大吼大叫：

recursion.fsx(5,9): error FS0001: This expression was expected to have type
    unit    
but here has type
    decimal

我在这里错过了什么？

Answer 1

从文档中：

每个分支中生成的值的类型必须匹配。如果没有显式else分支，则其类型为 unit 。因此，如果then分支的类型是 unit 以外的任何类型，则必须存在具有相同返回类型的else分支。

你错过了else说.

let rec recursiveSum inputs =
    let startState = 0.0m
    if List.isEmpty inputs then 0.0m
    elif List.length inputs = 1 then
        startState + inputs.Head
    else
        let t = List.tail inputs
        startState + inputs.Head + recursiveSum t

（注：注。我在这里使用了elif，而不是嵌套另一个if表达式;希望这不会太分散注意力。

也就是说，你涉及startState的逻辑是非常可疑的;它总是零，在这里真的没有任何用处。您的状态可能应该是一个参数而不是局部值，以便它可以用作累加器：

let recursiveSum inputs =
    let rec impl state inputs =
        if List.isEmpty inputs then state
        elif List.length inputs = 1 then
            state + inputs.Head
        else
            let t = List.tail inputs
            impl (state + inputs.Head) t
    impl 0.0m inputs

最后，让我们让它成为惯用语：

let recursiveSum inputs =
    let rec impl state inputs =
        match inputs with
          | []   -> state
          | [h]  -> state + h
          | h::t -> impl (state + h) t
    impl 0.0m inputs

可以缩短为

let recursiveSum inputs =
    let rec impl state = function
      | []   -> state
      | h::t -> impl (state + h) t
    impl 0.0m inputs

Answer 2

有了 ildjarns 的答案，我想我会建议一个人可以/应该一路走下去......

let rec fold f acc = function 
        | [] -> acc
        | [x] -> f x acc
        | h::t -> fold f (f h acc) t


let someDec = [0.1m; 0.2m]
let someStr = ["world"; "Hello "]
someDec
|> fold (+) 0.0m
someStr
|> fold (+) ""

let recursiveSum = fold (+) 0.0m    
someDec
|> recursiveSum

let recursiveStrAdd = fold (+) ""
someStr
|> recursiveStrAdd

someDec
|> recursiveSum

（我从来不记得在这里左或右，所以... ;-）