使用 xsl:when在 XSLT 中测试条件

Question

我有下面的xsl标签，我在其中获取fpml：period乘数和fpml：period的值，如下所示...XML 中的标记是 ：-

<fpml:periodMultiplier>1</fpml:periodMultiplier>
<fpml:period>Y</fpml:period>

在 XSL 中提取，如下所示

<Payindextenor>
<xsl:value-of select="../fpml:calculationPeriodDates
                        /fpml:calculationPeriodFrequency
                        /fpml:periodMultiplier" />
<xsl:value-of select="../fpml:calculationPeriodDates
                        /fpml:calculationPeriodFrequency
                        /fpml:period" />
</Payindextenor>

所以Payindextenor的值是1Y

现在我想在这个标签中输入空检查，因为在即将到来的XML中，fpml：period乘数和fpml：period也可能没有值。

所以我提出了下面的 XSL 实现，我尝试过如果任何值为 null，那么它应该打印 null 请告知它是否正确：-

<xsl:choose>
  <xsl:when test="../fpml:calculationPeriodDates
                    /fpml:calculationPeriodFrequency
                    /fpml:periodMultiplier
                  != ' ' 
                  and 
                  ../fpml:calculationPeriodDates
                    /fpml:calculationPeriodFrequency
                    /fpml:period 
                  != ' '">
    <xsl:value-of select="../fpml:calculationPeriodDates
                             /fpml:calculationPeriodFrequency
                            /fpml:periodMultiplier" />
   <xsl:value-of select="../fpml:calculationPeriodDates
                           /fpml:calculationPeriodFrequency
                           /fpml:period" />
  </xsl:when>
  <xsl:otherwise>
    <xsl:value-of select="'null'" />
  </xsl:otherwise>
</xsl:choose>

Answer 1

这与上一个问题的情况完全相同 - 您正在与包含单个空格的（非空）字符串' '进行比较，而您真正想要的是检查空字符串。 您可以使用与我为该问题建议的相同解决方案，并使用normalize-space进行测试（它将空字符串和仅包含空格的字符串视为"false"，将任何其他内容视为"true"）：

<xsl:choose>
  <xsl:when test="normalize-space(../fpml:calculationPeriodDates
                    /fpml:calculationPeriodFrequency
                    /fpml:periodMultiplier)
                  and 
                  normalize-space(../fpml:calculationPeriodDates
                    /fpml:calculationPeriodFrequency
                    /fpml:period)">
    <xsl:value-of select="../fpml:calculationPeriodDates
                             /fpml:calculationPeriodFrequency
                            /fpml:periodMultiplier" />
   <xsl:value-of select="../fpml:calculationPeriodDates
                           /fpml:calculationPeriodFrequency
                           /fpml:period" />
  </xsl:when>
  <xsl:otherwise>
    <xsl:value-of select="'null'" />
  </xsl:otherwise>
</xsl:choose>

这将处理fpml:periodMultiplier或fpml:period元素不存在的情况，以及它们存在但为空的情况。

Answer 2

正如 Ian Roberts 所说，将节点与单个空格进行比较与检查"null"非常不同，但假设您希望在periodMultiplier和period都为空时显示"null"，您可以这样做：

<xsl:variable name="freq" 
         select="../fpml:calculationPeriodDates/fpml:calculationPeriodFrequency" />
<xsl:choose>
  <xsl:when test="$freq/fpml:periodMultiplier != '' or 
                  $freq/fpml:period != ''">
    <xsl:value-of select="$freq/fpml:periodMultiplier" />
    <xsl:value-of select="$freq/fpml:period" />
  </xsl:when>
  <xsl:otherwise>
      <xsl:text>null</xsl:text>
  </xsl:otherwise>
</xsl:choose>