按特定顺序生成 xslt 输出

Question

我有一个大型的xml文档，如下所示：

<?xml version="1.0" encoding="UTF-8" ?>
<Data>
  <aTable>
    <aTableRow Col1="1" Col2="someText"/>
    <aTableRow Col1="2" Col2="newText"/>
    ...
  </aTable>
  <anotherTable>
    <anotherTableRow Col3="someText" Col4="42"/>
    <anotherTableRow Col3="myText" Col4="34"/>
    ...
  </anotherTable>
  ...
</Data>

我需要按照相应的 SQL INSERT 语句序列转换文档。像这样：

INSERT INTO aTable (Col1, Col2) VALUES (1, "someText")

我已经从"表"转换为相应的SQL语句，但是xslt输出是按照文档的相同顺序生成的。

有没有办法在表格之前有另一个表？

编辑

感谢您的评论和回答。读了它们，我意识到我原来的问题并不那么清楚。我会尝试添加更多细节。

我制作了一个模板，该模板可以正确转换一系列插入语句中的xml数据，假设此模板名为"insertGeneration"。

然后我写了这样的东西：

<xsl:template match="Data/anotherTable">
  <xsl:call-template name="insertGeneration"/>
</xsl:template>
<xsl:template match="Data/aTable">
  <xsl:call-template name="insertGeneration"/>
</xsl:template>

我希望输出按此顺序生成，即所有INSERT INTO anotherTable之前的所有INSERT INTO aTable。但生成的顺序与源文档相同。

我需要特定的顺序，否则在执行SQL脚本时可能会违反外键约束。

我的xslt处理器是Visual Studio 2005。好吧，不是紧凑的xslt处理器;-）

Answer 1

<xsl:output method="text" encoding="UTF-8" />
<xsl:template match="Data">
  <xsl:apply-templates select="*/*">
    <xsl:sort select="name(..)" case-order="lower-first" />
  </xsl:apply-templates>
</xsl:template>
<xsl:template match="Data/*/*">
  <xsl:text>INSERT INTO [</xsl:text>
  <xsl:value-of select="name(..)" />
  <xsl:text>] (</xsl:text>
  <xsl:apply-templates select="@*" mode="names" />
  <xsl:text>) VALUES (</xsl:text>
  <xsl:apply-templates select="@*" mode="values" />
  <xsl:text>)&#xA;</xsl:text>
</xsl:template>
<xsl:template match="Data/*/*/@*" mode="names">
  <xsl:text>[</xsl:text>
  <xsl:value-of select="name()" />
  <xsl:text>]</xsl:text>
  <xsl:if test="position() &lt; last()">, </xsl:if>
</xsl:template>
<xsl:template match="Data/*/*/@*" mode="values">
  <xsl:text>'</xsl:text>
  <xsl:call-template name="string-replace">
    <xsl:with-param name="search">'</xsl:with-param>
    <xsl:with-param name="replace">''</xsl:with-param>
  </xsl:call-template>
  <xsl:text>'</xsl:text>
  <xsl:if test="position() &lt; last()">, </xsl:if>
</xsl:template>

生成与 T-SQL 兼容的输出，如下所示：

INSERT INTO [anotherTable] ([Col3], [Col4]) VALUES ('someText', '42')
INSERT INTO [anotherTable] ([Col3], [Col4]) VALUES ('myText', '34')
INSERT INTO [aTable] ([Col1], [Col2]) VALUES ('1', 'some''Text')
INSERT INTO [aTable] ([Col1], [Col2]) VALUES ('2', 'newText')

如有必要，将代码调整为数据库的语法。

这使用按表名排列的字典顺序。如果需要不同的顺序，请相应地更改<xsl:sort>或使用多个单独的<xsl:apply-templates>来生成所需的序列。（请注意，某些 XSLT 处理器似乎忽略了 case-order 参数。

请注意，string-replace 是实现字符串替换函数（XSLT 1.0 所必需的）的命名模板。如果您有 XSLT 2.0，则可以简单地使用内置的string-replace()函数。

<xsl:template name="string-replace">
  <xsl:param name="subject" select="string()" />
  <xsl:param name="search" />
  <xsl:param name="replace" />
  <xsl:variable name="head" select="substring-before($subject, $search)" />
  <xsl:variable name="tail" select="substring-after($subject, $search)" />
  <xsl:variable name="found" select="$head or $tail" />
  <xsl:if test="not($found)">
    <xsl:value-of select="$subject" />
  </xsl:if>
  <xsl:if test="$found">
    <xsl:value-of select="$head" />
    <xsl:value-of select="$replace" />
    <xsl:call-template name="string-replace">
      <xsl:with-param name="subject" select="$tail" />
      <xsl:with-param name="search" select="$search" />
      <xsl:with-param name="replace" select="$replace" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>