当包含宏变量时，SAS 会在文件名中添加不需要的空格

Question

我正在使用 SAS 创建一个文本文件，并且我正在使用一个宏变量，在我的文本文件名中带有日期，以使其与其他类似文件区分开来。

我遇到的问题：

SAS 在文件名中间添加了两个不需要的空格。不需要的空格直接放在我的宏变量生成的文本之前

我确定这与我的正在使用的宏变量有关，但就其本身而言，该变量不包含任何空格。下面是我的代码：

proc format;
    picture dateFormat
    other = '%Y%0m%0d%0H%0M' (datatype=datetime);
run;
data _null_;
    dateTime=datetime();
    call symput('dateTime', put(dateTime,dateFormat.));
run;
%LET FILE = text_text_abc_&dateTime..txt;
filename out "/location/here/&FILE" termstr=crlf;
data _null_; set flatfile;
    /*file content is created in here*/
run;

导出的文件名将如下所示：

NOTE: The file OUT is:
    Filename=/location/here/text_text_abc_  201702010855.txt

如果有帮助，我正在使用 SAS 电子指南 7.1。

任何帮助不胜感激！谢谢大家！

Answer 1

您需要为图片格式分配适当的默认长度。SAS 应用默认默认长度 14，但您需要 12，例如

proc format;
    picture dateFormat (default=12)
    other = '%Y%0m%0d%0H%0M' (datatype=datetime);
run;

Answer 2

使用 call symputx() 而不是 call symput() ，则 SAS 将自动从写入宏变量的值中删除前导和尾随空格。实际上，只有在希望宏变量值具有前导或尾随空格的极少数情况下，才应使用call symput()。

运行这个小程序以查看差异。

data _null_;
  str='  XX  ';
  call symput('var1',str);
  call symputX('var2',str);
run;
%put |&var1|;
%put |&var2|;