我正在学习x64,我讨厌make,所以我试图让cmake使用NASM构建二进制文件。
这大致由 cmake 支持,但文档是废话。这就是我现在的工作,从堆栈溢出中拼凑出东西,然后删除所有不会破坏构建的内容:
cmake_minimum_required(VERSION 3.14)
set(CMAKE_ASM_NASM_LINK_EXECUTABLE "ld <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
set(CMAKE_ASM_NASM_OBJECT_FORMAT elf64)
project(test_project ASM_NASM)
set_source_files_properties(test.s PROPERTIES LANGUAGE ASM_NASM)
add_executable(test test.s)
if(CMAKE_BUILD_TYPE STREQUAL "Debug")
target_compile_options(test PRIVATE -g -Fdwarf)
endif()
所以有几个问题,为什么我必须告诉cmake使用ld
来链接,有没有更好的方法?
是否有类似于target_object_format
的东西可以用来指定对象格式而不是全局设置它?
有没有办法让 cmake 识别一个新的扩展名,而不是专门告诉它每个文件都是ASM_NASM的?
从源代码来看,ASM 构建仅由这组文档记录不佳的环境变量控制。
Michael正确地指出,默认情况下,CMAKE_ASM_LINK_EXECUTABLE
定义为:
<CMAKE_ASM_NASM_COMPILER> <FLAGS> <CMAKE_ASM_NASM_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>
这感觉像是一个错误,因为nasm
不做链接,也没有记录你需要改变这个环境变量。因此,要使用ld
我们需要设置:
set(CMAKE_ASM_NASM_LINK_EXECUTABLE "ld <CMAKE_ASM_NASM_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
接下来是源文件扩展名,默认情况下cmake仅识别.asm
和.nasm
。如果我们想扩展它,我们可以通过使用关联的环境变量来实现:
set(CMAKE_ASM_NASM_SOURCE_FILE_EXTENSIONS ${CMAKE_ASM_NASM_SOURCE_FILE_EXTENSIONS} s S)
最后是对象格式,不幸的是,这也是由环境变量控制的,因此我们可以使用以下方法全局更改它:
set(CMAKE_ASM_NASM_OBJECT_FORMAT elf64)
或者我们可以通过重新定义CMAKE_ASM_NASM_COMPILE_OBJECT
并创建我们自己的属性来获得更细粒度的控制(我不明白为什么这不是由 cmake 自己完成的):
enable_language(ASM_NASM)
set(CMAKE_ASM_NASM_COMPILE_OBJECT "<CMAKE_ASM_NASM_COMPILER> <INCLUDES> <FLAGS> -o <OBJECT> <SOURCE>")
# Create a compile option that operates on ASM_NASM files
# If the target has a property NASM_OBJ_FORMAT, use it, otherwise
# use the environment variable CMAKE_ASM_NASM_OBJECT_FORMAT
add_compile_options(
"$<$<COMPILE_LANGUAGE:ASM_NASM>:-f $<IF:$<BOOL:$<TARGET_PROPERTY:NASM_OBJ_FORMAT>>,
$<TARGET_PROPERTY:NASM_OBJ_FORMAT>, ${CMAKE_ASM_NASM_OBJECT_FORMAT}>>"
)
add_executable(test test.S)
set_target_properties(test PROPERTIES NASM_OBJ_FORMAT elf64)
在 cmake 3.15 之前,每次通过enable_language()
或project()
启用ASM_NASM
时,您都会覆盖CMAKE_ASM_NASM_COMPILE_OBJECT
。在版本>3.15 中,不需要enable_language()
调用,可以在project()
中正常启用该语言。
奖励,默认情况下CMAKE_ASM_NASM_FLAGS_DEBUG
为空,因此请随意将其设置为理智:
set(CMAKE_ASM_NASM_FLAGS_DEBUG "-g -Fdwarf")
老实说,cmake 中的 ASM 支持似乎半生不熟。它显然比 Make 或 Automake 更好,但不能像您希望的那样流畅地支持"现代"cmake 的习语。
> CMake 默认尝试使用编译器(在本例中为nasm
)作为链接器。显然,nasm
对链接一无所知,因此您必须通过指定要用于ASM_NASM
语言的链接器来覆盖该设置。
至于为源文件指定语言,您可以执行以下操作:
set(SOURCE_FILES test.s foo.s bar.s) # etc for all source files
set_source_files_properties(${SOURCE_FILES) PROPERTIES LANGUAGE ASM_NASM)
add_executable(test ${SOURCE_FILES})
这样,您只需列出所有文件一次。